The sample code on the Full Code tab can be used to create a user-defined format to apply color coding to cell values in PROC REPORT output. In a second user-defined format, inline formatting is used to draw an arrow symbol and add text to the adjacent cells.

There are several methods for finding out what symbols are available to you. For Windows 7, you can select Start ► Programs ► Accessories ► System Tools ► Character Map. For the font displayed, you can highlight a symbol and see the Unicode value for that symbol. An example follows of using inline formatting in PROC FORMAT to generate an upside-down smiley face and left arrow symbol in the Wingdings font using the Unicode function.

proc format;
   value testfmt
   low-52000="^S={font_face=Wingdings }^{unicode 4C} ^S={}Action needed"
   52000-high="^S={font_face=Wingdings}^{unicode DF} ^S={} Joe, good job"
   other=' ';
run;

The TESTFMT format can be used in place of the arrow format with the code on the Full Code tab. In addition to running the PROC FORMAT code above, use the TESTFMT format instead of the arrow format in the COMPUTE block as shown below:

compute arrow / char length=100;
   arrow=strip(put(Sales.sum,testfmt.));
endcomp;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

proc format;
   value salefmt low - 25000 = 'red'
               25000 - 52000 = 'dark yellow'
                52000 - high = 'green'
   ;
   
   value arrow 
         low-52000="^S={font_face=symbol}¬ ^S={font_face=arial} Johnny, look at this"
        52000-high="^S={font_face=symbol}¬ ^S={font_face=arial}Joe, good job"
             other=' '
   ;
run;

data test;
   input ID Sales;
   datalines; 
1 23000
1  2000
2 37000
3 48000
4 32000
5 125000
6 237000
;
run;

options nonumber nodate;
ods escapechar='^';
ods rtf file='test.rtf';

proc report nowd data=test;
   column ID Sales ARROW;
   define ID / group;
   define Sales / 'Sales' style(column)={font_weight=bold foreground=salefmt.};
   define arrow / computed ' ';
   compute arrow / char length=100;
      arrow=strip(put(Sales.sum,arrow.));
   endcomp;
run;

ods rtf close;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information