Sample 53334: Add a logo to every slide in the ODS destination for PowerPoint
 |  |  |  |  |  |
A logo can be placed in the background of each slide of a presentation that you generate using the ODS destination for PowerPoint.
For SAS® 9.4 (TS1M0), the first maintenance release for SAS 9.4 (TS1M1), and the second maintenance release for SAS 9.4 (TS1M2), use the following steps:
- Create an image that fills the entire slide background. Position the logo at the appropriate location in the image.
- Create a custom template with the BACKGROUNDIMAGE= attribute set in the Body style element.
- Specify the custom template in the ODS POWERPOINT statement using the STYLE= option.
Beginning with the third maintenance release for SAS 9.4 (TS1M3), you can customize the background of any number of slides in your presentation by specifying the BACKGROUNDIMAGE suboption in the OPTIONS option in the ODS POWERPOINT statement.
The sample code on the Full Code tab illustrates both techniques.
Tips for creating the logo image file: The image should have the same aspect ratio as your presentation. For a 4:3 presentation (the default), consider creating the image with 1024 x 768 pixels. For a 10:9 (widescreen) presentation, consider creating the image with 1280 x 720 pixels.
These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.
Create a custom template by setting the BACKGROUNDIMAGE= attribute to an appropriate image file and specify the template in the ODS POWERPOINT statement. In the third maintenance release for SAS 9.4 (TS1M3), use the BACKGROUNDIMAGE suboption in the ODS POWERPOINT statement to set a background image.
ods _all_ close;
title;
footnote;
options nodate nonumber;
/*** SAS 9.4 (TS1M0), SAS 9.4 (TS1M1), and SAS 9.4 (TS1M2) ***/
proc template;
define style styles.logo;
parent=styles.powerpointlight;
class body /
backgroundimage = "c:\saslogo_pptx.png";
end;
run;
ods powerpoint file='sample1.pptx' style=styles.logo nogtitle;
title 'Distribution of Blood Pressure';
proc sgplot data=sashelp.heart ;
histogram diastolic / fillattrs=graphdata1 transparency=0.7 binstart=40 binwidth=10;
density diastolic / lineattrs=graphdata1;
histogram systolic / fillattrs=graphdata2 transparency=0.5 binstart=40 binwidth=10;
density systolic / lineattrs=graphdata2;
keylegend / location=inside position=topright noborder across=2;
yaxis grid;
xaxis display=(nolabel) values=(0 to 300 by 50);
run;
title 'Blood Pressure Statistics';
proc means data=sashelp.heart n mean median std;
var diastolic systolic;
run;
ods powerpoint close;
/*** SAS 9.4 (TS1M3) ***/
ods powerpoint file="sample2.pptx" options(backgroundimage="c:\saslogo_pptx.png") nogtitle;
title 'Distribution of Blood Pressure';
proc sgplot data=sashelp.heart ;
histogram diastolic / fillattrs=graphdata1 transparency=0.7 binstart=40 binwidth=10;
density diastolic / lineattrs=graphdata1;
histogram systolic / fillattrs=graphdata2 transparency=0.5 binstart=40 binwidth=10;
density systolic / lineattrs=graphdata2;
keylegend / location=inside position=topright noborder across=2;
yaxis grid;
xaxis display=(nolabel) values=(0 to 300 by 50);
run;
title 'Blood Pressure Statistics';
proc means data=sashelp.heart n mean median std;
var diastolic systolic;
run;
ods powerpoint close;
These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.
A logo or image can be placed on every slide of a presentation using a customized style template. The image containing the logo must fill the entire slide background and should be the same aspect ratio as the presentation.
| Type: | Sample |
| Date Modified: | 2021-11-23 15:28:24 |
| Date Created: | 2014-06-27 15:10:40 |
Operating System and Release Information
| Product Family | Product | Host | SAS Release | |
| Starting | Ending | |||
| SAS System | Base SAS | Solaris for x64 | 9.4 TS1M0 | |
| Linux for x64 | 9.4 TS1M0 | |||
| HP-UX IPF | 9.4 TS1M0 | |||
| 64-bit Enabled Solaris | 9.4 TS1M0 | |||
| 64-bit Enabled HP-UX | 9.4 TS1M0 | |||
| 64-bit Enabled AIX | 9.4 TS1M0 | |||
| Windows 7 Professional x64 | 9.4 TS1M0 | |||
| Windows 7 Enterprise x64 | 9.4 TS1M0 | |||
| Microsoft Windows Server 2012 Std | 9.4 TS1M0 | |||
| Microsoft Windows Server 2012 R2 Std | 9.4 TS1M0 | |||
| Microsoft Windows Server 2012 R2 Datacenter | 9.4 TS1M0 | |||
| Microsoft Windows Server 2012 Datacenter | 9.4 TS1M0 | |||
| Microsoft Windows Server 2008 for x64 | 9.4 TS1M0 | |||
| Microsoft Windows Server 2008 R2 | 9.4 TS1M0 | |||
| Microsoft Windows 8.1 Pro 32-bit | 9.4 TS1M0 | |||
| Microsoft Windows 8.1 Pro | 9.4 TS1M0 | |||
| Microsoft Windows 8.1 Enterprise x64 | 9.4 TS1M0 | |||
| Microsoft Windows 8.1 Enterprise 32-bit | 9.4 TS1M0 | |||
| Microsoft Windows 8 Pro x64 | 9.4 TS1M0 | |||
| Microsoft Windows 8 Enterprise x64 | 9.4 TS1M0 | |||
| Microsoft® Windows® for x64 | 9.4 TS1M0 | |||
| Microsoft® Windows® for 64-Bit Itanium-based Systems | 9.4 TS1M0 | |||
| Z64 | 9.4 TS1M0 | |||
| z/OS | 9.4 TS1M0 | |||