Beginning with SAS 9.3, if you attempt to use the GRLINK device driver or attempt to create graphics output via SAS/CONNECT without specifying a device driver, the following error is written to the SAS log:

ERROR: Device was not specified.

It is still possible to use the GRLINK device driver. However, there are other methods available that work much better than using the GRLINK device driver. These methods are described below.

1. Remote submit code to SAS that writes the graphics output on the remote host to a graphics catalog. Then use the DOWNLOAD procedure to download the graphics catalog from the remote host to the local host. In a final step, use the GREPLAY procedure on the local machine to replay the downloaded graphics catalog. The sample SAS code below demonstrates this technique:

   rsubmit; 
   
   ods _all_ close; 
   ods listing; 
   goptions reset=all device=png nodisplay; 
   
   /* Your graph procedure code goes here */ 
   
   proc download incat=work.gseg outcat=work.gseg; 
   run; 
   
   endrsubmit; 
   
   goptions reset=all device=png; 
   
   %let workdir=%trim(%sysfunc(pathname(work))); 
   
   ods _ALL_ close; 
   ods html path = "&workdir" (url=none) 
            file = "sastest.html"; 
   
   proc greplay igout=work.gseg nofs; 
      replay _all_; 
   run; 
   quit; 
   
   ods html close; 
   ods listing; 
   

2. Remote submit graphics code that uses the ODS PDF statement to write a PDF file to a directory on your remote machine. Then use the DOWNLOAD procedure to download the PDF file to your local machine and use Adobe Acrobat Reader on your local machine to view the downloaded PDF file. The sample SAS code below demonstrates this technique:

   filename locref 'c:\temp\mylocalfile.pdf'; 
   
   rsubmit; 
   
   %let workdir=%trim(%sysfunc(pathname(work))); 
   
   ods _all_ close; 
   ods pdf file="&workdir./myremotefile.pdf"; 
   
   goptions reset=all device=sasprtc; 
   
   /* Your graph procedure code goes here */ 
   
   ods pdf close; 
   ods listing;  
   
   proc download infile="&workdir./myremotefile.pdf" outfile=locref binary; 
   run; 
   
   endrsubmit; 
   
   /* Use an X command similar to the following to open the downloaded */
   /* PDF file with Adobe Reader.  You will need to modify the         */
   /* X command below to point to the version of Adobe Acrobat that    */
   /* you have installed on Windows.                                   */
   
   x "'C:\Program Files (x86)\Adobe\Reader 10.0\Reader\AcroRd32' C:\temp\mylocalfile.pdf";
   

You should continue to use the GRLINK device driver only if you are not able to use either of the alternative methods described above. The sample SAS code below demonstrates how to use the GRLINK device driver starting with SAS 9.3:

%let workdir=%trim(%sysfunc(pathname(work))); 

libname gdevice0 "&workdir"; 

proc catalog c=sashelp.dgdevice; 
   copy out=gdevice0.devices; 
   select grlink / et=dev; 
run; 
quit; 

goptions device=grlink; 

/* Your graph procedure code goes here */

Operating System and Release Information