Gridded layout allows more than one table, graph, list, or text block to be placed on one slide with the ODS Destination for PowerPoint. There are three predefined layouts: TitleSlide, TitleAndContent, and TwoContent. To use a predefined layout, specify the layout name with the LAYOUT= option in the ODS POWERPOINT statement, as follows:

ods powerpoint file='example.pptx' layout=;

• The TitleSlide layout is used to create a title slide for the presentation.
• The TitleAndContent layout is used to create a slide with a title and content. More than one table, graph, list, or text box will fit on a slide if there is room.
• The TwoContent layout is used to create a two-column slide.

The sample code on the Full Code tab demonstrates the use of each layout. The code also demonstrates switching back to the default layout with LAYOUT=_NULL_ option. The slides can be viewed on the Output tab.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

The ODS Destination for PowerPoint supports the default layout as well three predefined gridded layouts.

---

ods _all_ close;
title;
footnote;
options nodate nonumber;

ods powerpoint file="sample.pptx" layout=titleslide;

proc odstext;
   p "IBM Stock" / style=PresentationTitle;
   p "2000-2005"/ style=PresentationTitle2;
run;

ods graphics on / border=off width=9in height=6in;

ods powerpoint layout=titleandcontent nogfootnote;

title "IBM Stock: volume vs close";
footnote "ODS Destination for PowerPoint";

proc sgplot data=sashelp.stocks;
   where stock="IBM" and year(date)>1999;
   vbar date / response=volume barwidth=0.5 fillattrs=(color=cx6590DC) dataskin=matte legendlabel="Volume";
   vline date / response=close y2axis lineattrs=(color=red) legendlabel="Close";
   xaxis label=' ' fitpolicy=thin;
   keylegend / noborder;
run;

ods powerpoint layout=_null_;

title "IBM Stock vs Competitors";
proc means data=sashelp.stocks max nway nonobs;
   where year(date)>1999;
   class stock;
   var volume;
run;

title "Overall Stats for IBM Stock";
ods powerpoint layout=twocontent;
footnote "ODS Destination for PowerPoint";
ods noptitle;

proc means data=sashelp.stocks mean;
   where stock="IBM" and year(date)>1999;
   class date;
   format date year4.;
   var volume;
run;

proc means data=sashelp.stocks mean;
   where stock="IBM" and year(date)>1999;
   class date;
   format date year4.;
   var close;
run;

ods powerpoint close;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Gridded layout allows more than one table, graph, list, or text block to be placed on one slide. There are three predefined layouts: TitleSlide, TitleAndContent, and TwoContent.

Type:

Sample

Date Modified:	2013-08-20 14:18:31
Date Created:	2013-07-23 15:19:33

Operating System and Release Information

Product Family	Product	Host	Product Release		SAS Release
			Starting	Ending	Starting	Ending
SAS System	Base SAS	z/OS	9.4		9.4 TS1M0
		Z64	9.4		9.4 TS1M0
		Microsoft® Windows® for x64	9.4		9.4 TS1M0
		Microsoft® Windows® for 64-Bit Itanium-based Systems	9.4		9.4 TS1M0
		Microsoft Windows 8 Enterprise	9.4		9.4 TS1M0
		Microsoft Windows 8 Pro	9.4		9.4 TS1M0
		Microsoft Windows Server 2008 R2 for x64	9.4		9.4 TS1M0
		Microsoft Windows Server 2008 for x64	9.4		9.4 TS1M0
		Microsoft Windows Server 2012 Datacenter	9.4		9.4 TS1M0
		Microsoft Windows Server 2012 Std	9.4		9.4 TS1M0
		Windows 7 Enterprise x64	9.4		9.4 TS1M0
		Windows 7 Professional x64	9.4		9.4 TS1M0
		64-bit Enabled AIX	9.4		9.4 TS1M0
		64-bit Enabled HP-UX	9.4		9.4 TS1M0
		64-bit Enabled Solaris	9.4		9.4 TS1M0
		HP-UX IPF	9.4		9.4 TS1M0
		Linux for x64	9.4		9.4 TS1M0
		Solaris for x64	9.4		9.4 TS1M0