• Correlation
• P-value
• Number of Observations

The ODS TRACE ON information statement used in conjunction with this code is shown below:

Output Added:
-------------
Name:       PearsonCorr
Label:      Pearson Correlations
Template:   base.corr.StackedMatrix
Path:       Corr.PearsonCorr

The Template name BASE.CORR.STACKEDMATRIX is used in the EDIT statement in PROC TEMPLATE to generate the desired changes.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

/* Add the WORK library to the ODS PATH */
ods path work.template(update) sashelp.tmplmst;
/*
The Matrix column is the correlation,
    Matrix2 is the p-value,
    Matrix3 is the number of observations contributing
    Matrix4 is not used by the PearsonCorr table*
   *With missing values in the data set, the COV option will produce a table with four rows, the 4th is Matrix4.
*/

proc format;
   value pvalsig low-.05 ="red"
                 .05-high="black";
run;
  
proc template;
   edit base.corr.stackedmatrix;
      column (RowName RowLabel) (Matrix) * (Matrix2) * (Matrix3) * (Matrix4);
      edit matrix2 ;
         style={foreground=pvalsig.};
      end;
    end;
run;

title;
footnote;
/* Remove "The CORR Procedure" from the output */
ods noptitle;
ods trace on;
ods escapechar="^";
options orientation=portrait nodate nonumber;

/* Use the JOURNAL style, which has less table lines and uses the Arial font */
ods rtf file="significance.rtf" startpage=no style=journal;
 
/* Exclude all other libraries other than SASHELP.TMPLMST from the ODS PATH. */
/* This is used for demonstration purposes to show the default PROC CORR     */
/* Pearsoncorr table's output.                                               */
ods path sashelp.tmplmst;

ods text="^S={font_face=Arial font_size=11pt font_weight=bold outputwidth=100% just=c}Default output"; 
/* Just show the Pearsoncorr table*/
ods select pearsoncorr; 
proc corr data=sashelp.iris;
   var sepallength sepalwidth petallength petalwidth; 
run;
  
ods text="^S={font_face=Arial font_size=11pt font_weight=bold outputwidth=100% just=c}Highlight significant Pvalues at the 95th Percentile"; 
/* Use the ODS PATH referenced above in order to pick up the changes created by PROC TEMPLATE */
ods path work.template(update) sashelp.tmplmst;
ods select pearsoncorr; 
proc corr data=sashelp.iris;
   var sepallength sepalwidth petallength petalwidth; 
run;
   
ods _all_ close;
ods trace off;
  
/* Delete the edited BASE.CORR.STACKEDMATRIX table so the changes do no persist in later output tables */
proc template; 
   delete base.corr.stackedmatrix;
run;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Click here to view the RTF output.

Operating System and Release Information