Assume that today the SAS library has 3 SAS data sets that you want to concatenate and create 1 SAS data set. The first step is to get a listing of the SAS data sets using PROC CONTENTS. Remove the duplicate names of the SAS data sets with PROC SORT. Next, a DATA _NULL_ step was used to obtain a count of the number of SAS data sets, and place the names of the SAS data sets into macro variables. Then, a macro containing a PROC APPEND nested inside a macro DO loop is used to append the SAS data sets into 1 SAS data set.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

/* Libname to allocate the SAS data library to be read - you will use your SAS data library 
instead of c:\temp */

libname abc 'c:\temp';


/* Run a PROC CONTENTS to create a SAS data set with the names of the SAS data sets in the SAS data 
library */

proc contents data=abc._all_ out=abccont(keep=memname) noprint;
run;


/* Eliminate any duplicate names of the SAS data set names stored in the SAS data set */

proc sort data=abccont nodupkey;
by memname;
run;


/* Run a DATA _NULL_ step to create 2 macro variables - one with the names of each SAS data set 
and the other with the final count of the number of SAS data sets */

data _null_;
  set abccont end=last;
  by memname;
  i+1;
  call symputx('name'||trim(left(put(i,8.))),memname);
  if last then call symputx('count',i);
run;


/* Macro containing the PROC APPEND that executes for each SAS data set you want to concatenate
together to create 1 SAS data set */

%macro combdsets;
%do i=1 %to &count;
proc append base=new data=abc.&&name&i force;
run;
%end;
%mend combdsets;


/* Execute the macro */

%combdsets

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information