45056 - Label the subgroups in a horizontal bar chart using PROC GCHART

Sample 45056: Label the subgroups in a horizontal bar chart using PROC GCHART

This sample illustrates how to use an Annotate data set to label the subgroups in a horizontal bar chart created with the GCHART procedure.

The graphics output on the Results tab was produced using SAS® 9.2. Submitting the sample code with releases of SAS prior to SAS 9.2 might produce different results.

/* Set the graphics environment */                                                                                                      
goptions reset=all cback=white border htitle=12pt htext=10pt;                                                                           
                                                                                                                                                                                                                                 
/* Sum the total sales by product for each country */                                                                                   
proc sort data=sashelp.prdsale out=prdsale;                                                                                             
   by product country;                                                                                                                  
run;                                                                                                                                    
proc means data=prdsale noprint;                                                                                                        
   by product country;                                                                                                                  
   var actual;                                                                                                                          
   output out=meansout sum=actual_sum;                                                                                                  
run;                                                                                                                                    
                                                                                                                                        
/* Create an Annotate data set to draw  */                                                                                              
/* the summed values for each subgroup. */                                                                                              
data barlabel;                                                                                                                          
   length function color $8;                                                                                                            
   retain xsys ysys '2' color 'black' when 'a';                                                                                         
   set meansout;                                                                                                                        
                                                                                                                                        
   function='label';                                                                                                                    
   midpoint=product;                                                                                                                    
   subgroup=country;                                                                                                                    
   position='<';                                                                                                                        
   text=trim(left(put(actual_sum,dollar8.0)));                                                                                          
run;                                                                                                                                    
                                                                                                                                        
/* Define the title */                                                                                                                  
title1 "Label the Subgroups in a Horizontal Bar Chart";                                                                                 
                                                                                                                                        
/* Define the axis characteristics */                                                                                                   
axis1 label=(angle=90 "Product")                                                                                                        
      value=(justify=right);                                                                                                            
axis2 label=("Actual Sales")                                                                                                            
      order=(0 to 160000 by 40000)                                                                                                      
      minor=(n=3);                                                                                                                      
                                                                                                                                        
/* Define legend options */                                                                                                         
legend1 frame;                                                                                                                          
                                                                                                                                        
/* Generate the graph */                                                                                                                
proc gchart data=sashelp.prdsale;                                                                                                       
   hbar product / subgroup=country                                                                                                      
                  sumvar=actual                                                                                                         
                  legend=legend1                                                                                                        
                  nostats                                                                                                               
                  maxis=axis1                                                                                                           
                  raxis=axis2                                                                                                           
                  annotate=barlabel;                                                                                                    
   format actual dollar8.0;                                                                                                             
run;                                                                                                                                    
quit;

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Type:	Sample
Topic:	SAS Reference ==> Procedures ==> GCHART Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Elements ==> Annotation Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Types ==> Charts ==> Bar

Date Modified:	2011-12-06 15:48:36
Date Created:	2011-12-06 14:00:33

Product Family	Product	Host	SAS Release
Product Family	Product	Host	Starting	Ending
SAS System	SAS/GRAPH	z/OS	9.2 TS1M0
		Microsoft® Windows® for 64-Bit Itanium-based Systems	9.2 TS1M0
		Microsoft Windows Server 2003 Datacenter 64-bit Edition	9.2 TS1M0
		Microsoft Windows Server 2003 Enterprise 64-bit Edition	9.2 TS1M0
		Microsoft Windows XP 64-bit Edition	9.2 TS1M0
		Microsoft® Windows® for x64	9.2 TS1M0
		Microsoft Windows Server 2003 Datacenter Edition	9.2 TS1M0
		Microsoft Windows Server 2003 Enterprise Edition	9.2 TS1M0
		Microsoft Windows Server 2003 Standard Edition	9.2 TS1M0
		Microsoft Windows XP Professional	9.2 TS1M0
		Windows Vista	9.2 TS1M0
		Windows Vista for x64	9.2 TS1M0
		64-bit Enabled AIX	9.2 TS1M0
		64-bit Enabled HP-UX	9.2 TS1M0
		64-bit Enabled Solaris	9.2 TS1M0
		HP-UX IPF	9.2 TS1M0
		Linux	9.2 TS1M0
		Linux for x64	9.2 TS1M0
		OpenVMS on HP Integrity	9.2 TS1M0
		Solaris for x64	9.2 TS1M0

Support

Sample 45056: Label the subgroups in a horizontal bar chart using PROC GCHART

Operating System and Release Information