44025 - Panel of liver function test (LFT) shift from baseline to maximum by treatment

Sample 44025: Panel of liver function test (LFT) shift from baseline to maximum by treatment

This sample uses the SGPANEL procedure to create a panel of scatter plots showing the liver function test (LFT) shift from baseline to maximum by treatment.

data LFTShift;
   keep Base Max Group Drug;
   retain absmax 0;
   length drug $15;
   length group $8;
   label Base="Baseline (/ULN)";
   label Max="Maximum (/ULN)";

   do group='ALAT', 'ALKPH', 'ASAT', 'BILTOT';
      do i=1 to 40;
         drug="Drug A (N=209)";
         base=(rannorm(2));
         max=(rannorm(2));
	 absmax=max(absmax, max(abs(base), abs(max)));
         output;

         drug="Drug B (N=405)";
         base=(rannorm(2));
         max=(rannorm(2));
	 absmax=max(absmax, max(abs(base), abs(max)));
         output;
      end;
   end;
   call symput("absmax", absmax);
run;

/* Normalize the data */
data LFTShiftNorm;
   keep Base Max Group Drug;
   set LFTShift;
   base=1+base/&absmax;
   max=1+max/&absmax;
run;

/* Create the graph */
ods listing close;
ods html file='lftshift.html' path='.';
ods graphics / reset width=600px height=300px noscale imagename="Panel of LFT Shift from Baseline";

title "Panel of LFT Shift from Baseline to Maximum by Treatment";
footnote1 j=l "For ALAT, ASAT and ALKPH, the Clinical Concern Level is 2 ULN;";
footnote2 j=l "For BILTOT, the CCL is 1.5 ULN: where ULN is the Upper Level of Normal Range";

proc sgpanel data=LFTShiftNorm;
   panelby group / layout=panel columns=4 spacing=10 novarname;
   scatter x=base y=max / group=drug;
   refline 1 1.5 2 / axis=Y lineattrs=(pattern=dash); 
   refline 1 1.5 2 / axis=X lineattrs=(pattern=dash);
   rowaxis integer min=0 max=4;
   colaxis integer min=0 max=4;
   keylegend / title="" noborder;
run;

ods html close;
ods listing;

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Type:	Sample
Topic:	Query and Reporting ==> Creating Reports ==> Graphical ==> Health and Life Sciences SAS Reference ==> Procedures ==> SGPANEL

Date Modified:	2011-10-19 08:38:22
Date Created:	2011-08-17 08:08:50

Product Family	Product	Host	SAS Release
Product Family	Product	Host	Starting	Ending
SAS System	SAS/GRAPH	z/OS	9.2 TS2M0
		Microsoft® Windows® for 64-Bit Itanium-based Systems	9.2 TS2M0
		Microsoft Windows Server 2003 Datacenter 64-bit Edition	9.2 TS2M0
		Microsoft Windows Server 2003 Enterprise 64-bit Edition	9.2 TS2M0
		Microsoft Windows XP 64-bit Edition	9.2 TS2M0
		Microsoft® Windows® for x64	9.2 TS2M0
		Microsoft Windows Server 2003 Datacenter Edition	9.2 TS2M0
		Microsoft Windows Server 2003 Enterprise Edition	9.2 TS2M0
		Microsoft Windows Server 2003 Standard Edition	9.2 TS2M0
		Microsoft Windows Server 2003 for x64	9.2 TS2M0
		Microsoft Windows Server 2008 for x64	9.2 TS2M0
		Microsoft Windows XP Professional	9.2 TS2M0
		Windows Vista	9.2 TS2M0
		Windows Vista for x64	9.2 TS2M0
		64-bit Enabled AIX	9.2 TS2M0
		64-bit Enabled HP-UX	9.2 TS2M0
		64-bit Enabled Solaris	9.2 TS2M0
		HP-UX IPF	9.2 TS2M0
		Linux	9.2 TS2M0
		Linux for x64	9.2 TS2M0
		OpenVMS on HP Integrity	9.2 TS2M0
		Solaris for x64	9.2 TS2M0

Support

Sample 44025: Panel of liver function test (LFT) shift from baseline to maximum by treatment

Operating System and Release Information