Usage Note 40724: Comparing covariance structures, testing covariance parameters using the COVTEST statement in PROC GLIMMIX
 |  |  |  |  |
When fitting a generalized linear mixed model with PROC GLIMMIX, more than one covariance structure may be appropriate. You can compare covariance structures to choose the structure that best fits your data. The available comparison methods depend on the type of model being fit, the estimation method being used, and the nature of the covariance structures being compared. Comparison and selection of a covariance structure should be done before examining the fixed effects tests.
In PROC GLIMMIX it is important to know whether a likelihood method (METHOD=LAPLACE or QUAD) or a pseudo-likelihood method (METHOD=RSPL, RMPL, MSPL, or MMPL) is used to estimate the model. Information criteria (AIC, BIC, etc.) are not reported for the pseudo-likelihood methods in PROC GLIMMIX since pseudo-likelihoods are not comparable between models, even when the models are nested. The COVTEST statement is needed to compare covariance structures in this situation.
Beginning in SAS 9.2 with the METHOD=LAPLACE or METHOD=QUAD option in the PROC GLIMMIX statement, the GLIMMIX procedure computes fit statistics for generalized linear mixed models based on maximum likelihood estimation. For these two estimation methods, this note describes ways that you can compare covariance structures. Note that when the METHOD=LAPLACE or METHOD=QUAD option is specified, the DDFM=KR option, the DDFM=SATTHERTH option, and R-side random effects cannot be specified. See the description of the METHOD= option in the GLIMMIX documentation for a complete list of options that are incompatible with METHOD=LAPLACE or METHOD=QUAD.
Regardless of the estimation method used in PROC GLIMMIX, the COVTEST statement (first available in SAS 9.2) allows you to compare different covariance structures based on a likelihood ratio test. However, when comparing two structures, one structure must be linearly nested in the other structure. For example, the COVTEST statement can be used to compare unstructured and compound symmetric covariance matrices, because the equal variances and equal covariances constraints needed to reduce the unstructured covariance matrix to the compound symmetric matrix are linear. However, the COVTEST statement cannot be used to compare unstructured and AR(1) matrices, or to compare Toeplitz and AR(1) matrices, because the constraints needed to reduce the unstructured and Toeplitz structures to the AR(1) structure are not linear. Additionally, it is recommended that you compare only the covariance structures that are meaningful for your data and area of application.
PROC GLIMMIX can also be used to fit a linear mixed model, which is a special case of the generalized linear mixed model. This note addresses the use of PROC GLIMMIX to compare covariance structures in linear mixed models.
The COVTEST statement allows you to make statistical inferences concerning the covariance parameters. It fits a reduced model based on the specification in the COVTEST statement and compares it with the full model based on the MODEL and RANDOM statements. The comparison is done using a likelihood ratio test. If a pseudo-likelihood estimation method is used in PROC GLIMMIX, the models are made comparable by basing the likelihoods on the final pseudo-data for the full model.
The data for the following examples were collected to compare two treatments for a respiratory illness at four randomly selected centers. Eligible patients were randomly assigned to one of the two treatments, P or A. At four visits while under treatment, each patient's respiration was determined to be good (1) or poor (0). In addition, each patient's sex, age, and baseline respiratory status were recorded.
The following statements create the data set and display the first 10 observations.
data resp;
input center id treatment $ sex $ age visit outcome baseline;
datalines;
.... see the Full Code tab for the complete data set ....
;
proc print data=resp(obs=10) noobs;
run;
|
These statements fit a model with CENTER as a random effect and use this R-side random effect to model the correlation among the repeated measures for each patient. The MODEL statement specifies the model for the fixed effects. The first RANDOM statement specifies CENTER as a random effect. The second RANDOM statement specifies an unstructured matrix for the correlations among the (linearized pseudo) measurements for each patient.
proc glimmix data=resp;
class id center sex treatment visit;
model outcome (event='1') = sex|treatment visit age baseline
/ dist=binary link=logit s;
random int / subject=center;
random _residual_ / subject=id(center) type=un;
run;
Below are the fit statistics and covariance estimates from the fitted model. Since a pseudo-likelihood estimation method is used (METHOD=RSPL), no likelihood-based fit statistics are produced in the Fit Statistics table. However, you can use the COVTEST statement to compare appropriate covariance structures as illustrated below.
COVTEST statement: Using keywords to test specific hypotheses
Common questions in mixed modeling include whether variance components are zero, whether random effects are independent, and whether rows (and columns) can be added or removed from an unstructured covariance matrix. A keyword can be specified in the COVTEST statement to test such hypotheses. See the description of the COVTEST statement in the GLIMMIX documentation for details on the available keywords and the hypotheses they test. For example, the ZEROG option in the COVTEST statement below tests whether the G matrix can be reduced to a zero matrix which eliminates all G-side random effects from the model. Effectively, this option tests whether the random CENTER effect is necessary.
proc glimmix data=resp;
class id center sex treatment visit;
model outcome (event='1') = sex|treatment visit age baseline
/ dist=binary link=logit;
random int / subject=center;
random _residual_ / subject=id(center) type=un;
covtest 'No random Center effect' zeroG;
run;
The results from the COVTEST statement appear below. The -2 Residual Log Pseudo-Likelihood is 1997.29 for the model without the random CENTER effect. The likelihood ratio chi-square test compares the full model specified in the MODEL and RANDOM statements with the reduced model omitting the random CENTER effect. The large p-value (p=0.1915) indicates that the model without the random CENTER effect fits the data as well as the model with the random CENTER effect. This suggests that the CENTER effect is not necessary.
MI: P-value based on a mixture of chi-squares.
| ||||||||||||||||||
The Note column along with the table's footnote informs you that mixture distributions are used in the calculation of the p-value. When the parameters under the null hypothesis fall on the boundary of the parameter space, the distribution of the likelihood ratio statistic can be a complicated mixture of distributions. In certain situations it is known to be a relatively straightforward mixture of central chi-square distributions. When the GLIMMIX procedure recognizes the model and hypothesis as a case for which the mixture is readily available, the p-value of the likelihood ratio test is determined accordingly as a linear combination of central chi-square probabilities.
The following statements fit the model omitting the random CENTER effect.
proc glimmix data=resp;
class id center sex treatment visit;
model outcome (event='1') = sex|treatment visit age baseline
/ dist=binary link=logit;
random _residual_ / subject=id(center) type=un;
run;
The fit statistics for this model appears below. Note that the -2 Residual Log Pseudo-Likelihood is 1981.96, which is different from 1997.29 reported previously by the COVTEST statement. This is because the COVTEST statement computes the residual log pseudo-likelihood for the ZeroG (reduced) model based on the final linearized pseudo-data from the full model. This makes the likelihood ratio test possible when pseudo-likelihood estimation is used. A likelihood ratio test cannot be computed by fitting the two models separately because the pseudo-data changes from iteration to iteration. In order to construct a valid likelihood ratio test, the data models must be the same for both models when computing their -2 residual log pseudo-likelihood values. The COVTEST statement fixes the data for the pseudo-likelihood computations between the two models.
| ||||||||
COVTEST statement: Using a value-list or the TESTDATA= option
You can specify a list of values or a data set in the COVTEST statement. For example, the following statements provide a test for zero covariance. The position of a coefficient in the value-list in the COVTEST statement corresponds to the position of the parameter in the "Covariance Parameter Estimates" table. A missing value (.) means the covariance parameter is to be estimated, a zero value fixes the parameter at zero. By matching the value-list in the COVTEST statement below with the "Covariance Parameter Estimates" table above, you can see that all covariances are set to zero and all variances are estimated. The ESTIMATES option displays the estimates of the covariance parameters under the null hypothesis specified in the COVTEST statement — zero covariance in this example.
proc glimmix data=resp;
class id center sex treatment visit;
model outcome (event='1') = sex|treatment visit age baseline
/ dist=binary link=logit;
random int / subject=center;
random _residual_ / subject=id(center) type=un;
covtest 'zero covariance' . . 0 . 0 0 . 0 0 0 . / estimates;
run;
The results from the COVTEST statement appear below. The small p-value (p<.0001) indicates that the zero covariance hypothesis is rejected. A model with non-zero covariance fits the data better than the zero covariance model.
DF: P-value based on a chi-square with DF degrees of freedom.
| ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
COVTEST statement: Using a general contrast
Suppose you want to test the hypothesis that the covariance matrix exhibits equal variances and equal covariances, also known as compound symmetry. You can write a general contrast to perform such a test. The COVTEST statement below defines a contrast with multiple degrees of freedom. The coefficients in each row (rows are separated by commas) correspond to the ordering of covariance parameters in the "Covariance Parameter Estimates" table. The first row compares covariance parameters UN(1,1) and UN(2,2). The next row compares UN(1,1) and UN(3,3). The third row compares UN(1,1) and UN(4,4). The covariances are compared in the remaining rows — the fourth row compares UN(2,1) and UN(3,1), the fifth row compares UN(2,1) and UN(3,2), etc. The resulting overall test is for equal variances and equal covariances.
proc glimmix data=resp;
class id center sex treatment visit;
model outcome (event='1') = sex|treatment visit age baseline
/ dist=binary link=logit;
random int / subject=center;
random _residual_ / subject=id(center) type=un;
covtest 'CS' general 0 1 0 -1,
0 1 0 0 0 0 -1,
0 1 0 0 0 0 0 0 0 0 -1,
0 0 1 0 -1,
0 0 1 0 0 -1,
0 0 1 0 0 0 0 -1,
0 0 1 0 0 0 0 0 -1,
0 0 1 0 0 0 0 0 0 -1 / estimates;
run;
In the results from the COVTEST statement, the large p-value for the likelihood ratio test (p=0.3229) indicates no significant deviation from the compound symmetric structure. The ESTIMATES option displays the variance-covariance parameter estimates for the compound symmetric structure. The variance is estimated to be 1.03 and the covariance is estimated to be 0.364.
DF: P-value based on a chi-square with DF degrees of freedom.
| ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
The COVTEST statement can also be used to test for equal variances (homogeneity), zero slope variance for the random coefficients model, zero covariance between the intercept and slope in a random coefficients model, just to name a few. For more information on the COVTEST statement syntax and examples, see the description of the COVTEST statement in the GLIMMIX documentation.
Operating System and Release Information
| Product Family | Product | System | SAS Release | |
| Reported | Fixed* | |||
| SAS System | SAS/STAT | z/OS | ||
| OpenVMS VAX | ||||
| Microsoft® Windows® for 64-Bit Itanium-based Systems | ||||
| Microsoft Windows Server 2003 Datacenter 64-bit Edition | ||||
| Microsoft Windows Server 2003 Enterprise 64-bit Edition | ||||
| Microsoft Windows XP 64-bit Edition | ||||
| Microsoft® Windows® for x64 | ||||
| OS/2 | ||||
| Microsoft Windows 95/98 | ||||
| Microsoft Windows 2000 Advanced Server | ||||
| Microsoft Windows 2000 Datacenter Server | ||||
| Microsoft Windows 2000 Server | ||||
| Microsoft Windows 2000 Professional | ||||
| Microsoft Windows NT Workstation | ||||
| Microsoft Windows Server 2003 Datacenter Edition | ||||
| Microsoft Windows Server 2003 Enterprise Edition | ||||
| Microsoft Windows Server 2003 Standard Edition | ||||
| Microsoft Windows Server 2003 for x64 | ||||
| Microsoft Windows Server 2008 | ||||
| Microsoft Windows Server 2008 for x64 | ||||
| Microsoft Windows XP Professional | ||||
| Windows 7 Enterprise 32 bit | ||||
| Windows 7 Enterprise x64 | ||||
| Windows 7 Home Premium 32 bit | ||||
| Windows 7 Home Premium x64 | ||||
| Windows 7 Professional 32 bit | ||||
| Windows 7 Professional x64 | ||||
| Windows 7 Ultimate 32 bit | ||||
| Windows 7 Ultimate x64 | ||||
| Windows Millennium Edition (Me) | ||||
| Windows Vista | ||||
| Windows Vista for x64 | ||||
| 64-bit Enabled AIX | ||||
| 64-bit Enabled HP-UX | ||||
| 64-bit Enabled Solaris | ||||
| ABI+ for Intel Architecture | ||||
| AIX | ||||
| HP-UX | ||||
| HP-UX IPF | ||||
| IRIX | ||||
| Linux | ||||
| Linux for x64 | ||||
| Linux on Itanium | ||||
| OpenVMS Alpha | ||||
| OpenVMS on HP Integrity | ||||
| Solaris | ||||
| Solaris for x64 | ||||
| Tru64 UNIX | ||||
data resp;
input center id treatment $ sex $ age visit outcome baseline;
datalines;
1 1 P M 46 1 0 0
1 1 P M 46 2 0 0
1 1 P M 46 3 0 0
1 1 P M 46 4 0 0
1 2 P M 28 1 0 0
1 2 P M 28 2 0 0
1 2 P M 28 3 0 0
1 2 P M 28 4 0 0
1 3 A M 23 1 1 1
1 3 A M 23 2 1 1
1 3 A M 23 3 1 1
1 3 A M 23 4 1 1
1 4 P M 44 1 1 1
1 4 P M 44 2 1 1
1 4 P M 44 3 1 1
1 4 P M 44 4 0 1
1 5 P F 13 1 1 1
1 5 P F 13 2 1 1
1 5 P F 13 3 1 1
1 5 P F 13 4 1 1
1 6 A M 34 1 0 0
1 6 A M 34 2 0 0
1 6 A M 34 3 0 0
1 6 A M 34 4 0 0
1 7 P M 43 1 1 0
1 7 P M 43 2 0 0
1 7 P M 43 3 1 0
1 7 P M 43 4 1 0
1 8 A M 28 1 0 0
1 8 A M 28 2 0 0
1 8 A M 28 3 0 0
1 8 A M 28 4 0 0
1 9 A M 31 1 1 1
1 9 A M 31 2 1 1
1 9 A M 31 3 1 1
1 9 A M 31 4 1 1
1 10 P M 37 1 0 1
1 10 P M 37 2 1 1
1 10 P M 37 3 1 1
1 10 P M 37 4 0 1
1 11 A M 30 1 1 1
1 11 A M 30 2 1 1
1 11 A M 30 3 1 1
1 11 A M 30 4 1 1
1 12 A M 14 1 1 0
1 12 A M 14 2 1 0
1 12 A M 14 3 1 0
1 12 A M 14 4 0 0
1 13 P M 23 1 1 1
1 13 P M 23 2 0 1
1 13 P M 23 3 0 1
1 13 P M 23 4 0 1
1 14 P M 30 1 0 0
1 14 P M 30 2 0 0
1 14 P M 30 3 0 0
1 14 P M 30 4 0 0
1 15 P M 20 1 1 1
1 15 P M 20 2 1 1
1 15 P M 20 3 1 1
1 15 P M 20 4 1 1
1 16 A M 22 1 0 0
1 16 A M 22 2 0 0
1 16 A M 22 3 0 0
1 16 A M 22 4 1 0
1 17 P M 25 1 0 0
1 17 P M 25 2 0 0
1 17 P M 25 3 0 0
1 17 P M 25 4 0 0
1 18 A F 47 1 0 0
1 18 A F 47 2 1 0
1 18 A F 47 3 1 0
1 18 A F 47 4 1 0
1 19 P F 31 1 0 0
1 19 P F 31 2 0 0
1 19 P F 31 3 0 0
1 19 P F 31 4 0 0
1 20 A M 20 1 1 1
1 20 A M 20 2 0 1
1 20 A M 20 3 1 1
1 20 A M 20 4 0 1
1 21 A M 26 1 1 0
1 21 A M 26 2 0 0
1 21 A M 26 3 1 0
1 21 A M 26 4 0 0
1 22 A M 46 1 1 1
1 22 A M 46 2 1 1
1 22 A M 46 3 1 1
1 22 A M 46 4 1 1
1 23 A M 32 1 1 1
1 23 A M 32 2 1 1
1 23 A M 32 3 1 1
1 23 A M 32 4 1 1
1 24 A M 48 1 1 0
1 24 A M 48 2 0 0
1 24 A M 48 3 0 0
1 24 A M 48 4 0 0
1 25 P F 35 1 0 0
1 25 P F 35 2 0 0
1 25 P F 35 3 0 0
1 25 P F 35 4 0 0
1 26 A M 26 1 0 0
1 26 A M 26 2 0 0
1 26 A M 26 3 0 0
1 26 A M 26 4 0 0
1 27 P M 23 1 1 1
1 27 P M 23 2 0 1
1 27 P M 23 3 1 1
1 27 P M 23 4 1 1
2 1 P F 36 1 1 0
2 1 P F 36 2 1 0
2 1 P F 36 3 0 0
2 1 P F 36 4 0 0
2 2 P M 19 1 1 0
2 2 P M 19 2 1 0
2 2 P M 19 3 0 0
2 2 P M 19 4 0 0
2 3 A M 28 1 0 0
2 3 A M 28 2 0 0
2 3 A M 28 3 0 0
2 3 A M 28 4 0 0
2 4 P M 37 1 0 0
2 4 P M 37 2 0 0
2 4 P M 37 3 0 0
2 4 P M 37 4 0 0
2 5 A M 23 1 1 0
2 5 A M 23 2 1 0
2 5 A M 23 3 1 0
2 5 A M 23 4 1 0
2 6 A M 30 1 1 1
2 6 A M 30 2 1 1
2 6 A M 30 3 1 1
2 6 A M 30 4 0 1
2 7 P M 15 1 0 0
2 7 P M 15 2 1 0
2 7 P M 15 3 1 0
2 7 P M 15 4 0 0
2 8 A M 26 1 0 0
2 8 A M 26 2 0 0
2 8 A M 26 3 1 0
2 8 A M 26 4 0 0
2 9 P F 45 1 0 0
2 9 P F 45 2 0 0
2 9 P F 45 3 0 0
2 9 P F 45 4 0 0
2 10 A M 31 1 0 0
2 10 A M 31 2 1 0
2 10 A M 31 3 0 0
2 10 A M 31 4 0 0
2 11 A M 50 1 0 0
2 11 A M 50 2 0 0
2 11 A M 50 3 0 0
2 11 A M 50 4 0 0
2 12 P M 28 1 0 0
2 12 P M 28 2 0 0
2 12 P M 28 3 0 0
2 12 P M 28 4 0 0
2 13 P M 26 1 0 0
2 13 P M 26 2 0 0
2 13 P M 26 3 0 0
2 13 P M 26 4 0 0
2 14 P M 14 1 0 0
2 14 P M 14 2 0 0
2 14 P M 14 3 0 0
2 14 P M 14 4 1 0
2 15 A M 31 1 0 0
2 15 A M 31 2 1 0
2 15 A M 31 3 0 0
2 15 A M 31 4 0 0
2 16 P M 13 1 1 1
2 16 P M 13 2 1 1
2 16 P M 13 3 1 1
2 16 P M 13 4 1 1
2 17 P M 27 1 0 0
2 17 P M 27 2 0 0
2 17 P M 27 3 0 0
2 17 P M 27 4 0 0
2 18 P M 26 1 1 0
2 18 P M 26 2 0 0
2 18 P M 26 3 1 0
2 18 P M 26 4 1 0
2 19 P M 49 1 0 0
2 19 P M 49 2 0 0
2 19 P M 49 3 0 0
2 19 P M 49 4 0 0
2 20 P M 63 1 0 0
2 20 P M 63 2 0 0
2 20 P M 63 3 0 0
2 20 P M 63 4 0 0
2 21 A M 57 1 1 1
2 21 A M 57 2 1 1
2 21 A M 57 3 1 1
2 21 A M 57 4 1 1
2 22 P M 27 1 1 1
2 22 P M 27 2 1 1
2 22 P M 27 3 1 1
2 22 P M 27 4 1 1
2 23 A M 22 1 0 0
2 23 A M 22 2 1 0
2 23 A M 22 3 1 0
2 23 A M 22 4 1 0
2 24 A M 15 1 0 0
2 24 A M 15 2 1 0
2 24 A M 15 3 1 0
2 24 A M 15 4 1 0
2 25 P M 43 1 0 0
2 25 P M 43 2 0 0
2 25 P M 43 3 1 0
2 25 P M 43 4 0 0
2 26 A F 32 1 0 0
2 26 A F 32 2 0 0
2 26 A F 32 3 1 0
2 26 A F 32 4 0 0
2 27 A M 11 1 1 1
2 27 A M 11 2 1 1
2 27 A M 11 3 1 1
2 27 A M 11 4 0 1
2 28 P M 24 1 1 1
2 28 P M 24 2 1 1
2 28 P M 24 3 1 1
2 28 P M 24 4 1 1
2 29 A M 25 1 1 0
2 29 A M 25 2 1 0
2 29 A M 25 3 0 0
2 29 A M 25 4 1 0
3 1 P F 39 1 0 0
3 1 P F 39 2 0 0
3 1 P F 39 3 0 0
3 1 P F 39 4 0 0
3 2 A M 25 1 1 1
3 2 A M 25 2 1 1
3 2 A M 25 3 1 1
3 2 A M 25 4 0 1
3 3 A M 58 1 1 1
3 3 A M 58 2 1 1
3 3 A M 58 3 1 1
3 3 A M 58 4 1 1
3 4 P F 51 1 1 1
3 4 P F 51 2 0 1
3 4 P F 51 3 1 1
3 4 P F 51 4 1 1
3 5 P F 32 1 0 1
3 5 P F 32 2 0 1
3 5 P F 32 3 1 1
3 5 P F 32 4 1 1
3 6 P M 45 1 1 1
3 6 P M 45 2 0 1
3 6 P M 45 3 0 1
3 6 P M 45 4 0 1
3 7 P F 44 1 1 1
3 7 P F 44 2 1 1
3 7 P F 44 3 1 1
3 7 P F 44 4 1 1
3 8 P F 48 1 0 0
3 8 P F 48 2 0 0
3 8 P F 48 3 0 0
3 8 P F 48 4 0 0
3 9 A M 26 1 1 0
3 9 A M 26 2 1 0
3 9 A M 26 3 1 0
3 9 A M 26 4 1 0
3 10 A M 14 1 1 0
3 10 A M 14 2 1 0
3 10 A M 14 3 1 0
3 10 A M 14 4 1 0
3 11 P F 48 1 0 0
3 11 P F 48 2 0 0
3 11 P F 48 3 0 0
3 11 P F 48 4 0 0
3 12 A M 13 1 1 1
3 12 A M 13 2 1 1
3 12 A M 13 3 1 1
3 12 A M 13 4 1 1
3 13 P M 20 1 1 0
3 13 P M 20 2 1 0
3 13 P M 20 3 1 0
3 13 P M 20 4 1 0
3 14 A M 37 1 1 1
3 14 A M 37 2 0 1
3 14 A M 37 3 0 1
3 14 A M 37 4 1 1
3 15 A M 25 1 1 1
3 15 A M 25 2 1 1
3 15 A M 25 3 1 1
3 15 A M 25 4 1 1
3 16 A M 20 1 1 0
3 16 A M 20 2 1 0
3 16 A M 20 3 1 0
3 16 A M 20 4 1 0
3 17 P F 58 1 1 0
3 17 P F 58 2 0 0
3 17 P F 58 3 0 0
3 17 P F 58 4 0 0
3 18 P M 38 1 1 1
3 18 P M 38 2 0 1
3 18 P M 38 3 0 1
3 18 P M 38 4 0 1
3 19 A M 55 1 1 1
3 19 A M 55 2 1 1
3 19 A M 55 3 1 1
3 19 A M 55 4 1 1
3 20 A M 24 1 1 1
3 20 A M 24 2 1 1
3 20 A M 24 3 1 1
3 20 A M 24 4 1 1
3 21 P F 36 1 1 1
3 21 P F 36 2 0 1
3 21 P F 36 3 0 1
3 21 P F 36 4 1 1
3 22 P M 36 1 1 0
3 22 P M 36 2 1 0
3 22 P M 36 3 1 0
3 22 P M 36 4 1 0
3 23 A F 60 1 1 1
3 23 A F 60 2 1 1
3 23 A F 60 3 1 1
3 23 A F 60 4 1 1
3 24 P M 15 1 0 1
3 24 P M 15 2 0 1
3 24 P M 15 3 1 1
3 24 P M 15 4 1 1
3 25 A M 25 1 0 0
3 25 A M 25 2 1 0
3 25 A M 25 3 1 0
3 25 A M 25 4 1 0
3 26 A M 35 1 1 1
3 26 A M 35 2 1 1
3 26 A M 35 3 1 1
3 26 A M 35 4 1 1
3 27 A M 19 1 1 1
3 27 A M 19 2 0 1
3 27 A M 19 3 1 1
3 27 A M 19 4 1 1
3 28 P F 31 1 1 1
3 28 P F 31 2 1 1
3 28 P F 31 3 1 1
3 28 P F 31 4 1 1
3 29 A M 21 1 1 1
3 29 A M 21 2 1 1
3 29 A M 21 3 1 1
3 29 A M 21 4 1 1
4 1 A F 37 1 1 0
4 1 A F 37 2 1 0
4 1 A F 37 3 1 0
4 1 A F 37 4 1 0
4 2 P M 52 1 1 0
4 2 P M 52 2 1 0
4 2 P M 52 3 1 0
4 2 P M 52 4 1 0
4 3 A M 55 1 0 0
4 3 A M 55 2 1 0
4 3 A M 55 3 1 0
4 3 A M 55 4 0 0
4 4 P M 19 1 0 1
4 4 P M 19 2 0 1
4 4 P M 19 3 1 1
4 4 P M 19 4 1 1
4 5 P M 20 1 0 1
4 5 P M 20 2 1 1
4 5 P M 20 3 1 1
4 5 P M 20 4 1 1
4 6 P M 42 1 0 1
4 6 P M 42 2 0 1
4 6 P M 42 3 0 1
4 6 P M 42 4 0 1
4 7 A M 41 1 1 1
4 7 A M 41 2 1 1
4 7 A M 41 3 1 1
4 7 A M 41 4 1 1
4 8 A M 52 1 0 0
4 8 A M 52 2 0 0
4 8 A M 52 3 0 0
4 8 A M 52 4 0 0
4 9 P F 47 1 1 0
4 9 P F 47 2 1 0
4 9 P F 47 3 0 0
4 9 P F 47 4 1 0
4 10 P M 11 1 1 1
4 10 P M 11 2 1 1
4 10 P M 11 3 1 1
4 10 P M 11 4 1 1
4 11 P M 14 1 0 0
4 11 P M 14 2 0 0
4 11 P M 14 3 1 0
4 11 P M 14 4 0 0
4 12 P M 15 1 1 1
4 12 P M 15 2 1 1
4 12 P M 15 3 1 1
4 12 P M 15 4 1 1
4 13 P M 66 1 1 1
4 13 P M 66 2 1 1
4 13 P M 66 3 1 1
4 13 P M 66 4 1 1
4 14 A M 34 1 1 0
4 14 A M 34 2 1 0
4 14 A M 34 3 0 0
4 14 A M 34 4 1 0
4 15 P M 43 1 0 0
4 15 P M 43 2 0 0
4 15 P M 43 3 0 0
4 15 P M 43 4 0 0
4 16 P M 33 1 1 1
4 16 P M 33 2 1 1
4 16 P M 33 3 0 1
4 16 P M 33 4 1 1
4 17 P M 48 1 1 1
4 17 P M 48 2 0 1
4 17 P M 48 3 0 1
4 17 P M 48 4 0 1
4 18 A M 20 1 0 0
4 18 A M 20 2 0 0
4 18 A M 20 3 0 0
4 18 A M 20 4 0 0
4 19 P F 39 1 0 1
4 19 P F 39 2 1 1
4 19 P F 39 3 0 1
4 19 P F 39 4 0 1
4 20 A M 28 1 1 0
4 20 A M 28 2 0 0
4 20 A M 28 3 0 0
4 20 A M 28 4 0 0
4 21 P F 38 1 0 0
4 21 P F 38 2 0 0
4 21 P F 38 3 0 0
4 21 P F 38 4 0 0
4 22 A M 43 1 1 1
4 22 A M 43 2 1 1
4 22 A M 43 3 1 1
4 22 A M 43 4 0 1
4 23 A F 39 1 1 0
4 23 A F 39 2 1 0
4 23 A F 39 3 1 0
4 23 A F 39 4 1 0
4 24 A M 68 1 1 0
4 24 A M 68 2 1 0
4 24 A M 68 3 1 0
4 24 A M 68 4 1 0
4 25 A F 63 1 1 1
4 25 A F 63 2 1 1
4 25 A F 63 3 1 1
4 25 A F 63 4 1 1
4 26 A M 31 1 1 1
4 26 A M 31 2 1 1
4 26 A M 31 3 1 1
4 26 A M 31 4 1 1
;
| Type: | Usage Note |
| Priority: | |
| Topic: | Analytics ==> Mixed Models SAS Reference ==> Procedures ==> GLIMMIX SAS Reference ==> Procedures ==> MIXED |
| Date Modified: | 2010-11-10 12:45:08 |
| Date Created: | 2010-08-29 23:57:57 |