• Print |
• E-mail  |
• Bookmark

proc format;
  value matfmt
    1='1 mo'
    2='3 mo'
    3='6 mo'
    6='1 yr'
    7='2 yr'
    8='3 yr'
    9='5 yr'
    11='10 yr '
    14='30 yr';
  picture yldfmt
    low-high='9%';
run;

data yield;
  input matcur yldcur mat1mo yld1mo mat1yr yld1yr; label yldcur='January 2008' yld1mo = 'December 2007'
      yld1yr = 'January 2007';
  format mat1yr matfmt. mat1mo matfmt. matcur matfmt.
    yldcur yldfmt. yld1mo yldfmt. yld1yr yldfmt.; 
  datalines;
1    2.63    1    2.76    1    4.97
2    2.86    2    3.04    2    5.12
3    2.86    3    3.37    3    5.16
6    2.69    6    3.31    6    5.07
7    2.36    7    3.19    7    4.89
8    2.39    8    3.2     8    4.8
9    2.86    9    3.53    9    4.75
11   4.3     11   4.6     11   4.94
14   4.28    14   4.55    14   4.85
;
run;

title 'Government Bond Yield Curve';

ods html file='BondMaturity' path='.' style=curve;
ods graphics / reset width=600px height=400px imagename='BondMaturity' imagefmt=gif;

proc sgplot data=yield cycleattrs noautolegend;
  band  x=mat1yr upper=yld1yr  lower=0/  name='b1' legendlabel='January 2007';
  band  x=mat1mo upper=yld1mo lower=0 /  name='b2' legendlabel='December 2007';
  band  x=matcur upper=yldcur lower=0 / name='b3' legendlabel='January 2008';
  series  x=mat1yr y=yld1yr / markers markerattrs=(color=white symbol=circlefilled)lineattrs=(pattern=solid);
  series  x=mat1mo y=yld1mo / markers markerattrs=(color=white symbol=circlefilled)lineattrs=(pattern=solid);
  series  x=matcur y=yldcur / markers markerattrs=(color=white symbol=circlefilled)lineattrs=(pattern=solid);
  needle  x=matcur y=yld1yr / lineattrs=(color=white pattern=solid); 
  yaxis label='Bond Yield' offsetmin=0; 
  xaxis values=(1 2 3 6 7 8 9 11 14) label='Bond Maturity';
  keylegend 'b1' 'b2' 'b3'; 
run;

ods html close;
ods listing;

Operating System and Release Information