Providing software solutions since 1976

• Log in
• Create profile
• Welcome
  [Log out]
• Edit profile

• Print  |
• Feedback  |
• Share

  • E-mail

  
  
  

  E-mail This Page

  Your Name:*
  Your E-mail:*
  Recipient E-mail:*
  Send a copy to me
  Personal Message:
  
  

  * indicates a required field

PROC BOXPLOT has no option to draw the whiskers in percentile units, such as whiskers drawn to the 5^th and 95^th percentiles, and there is no option to omit the whiskers altogether. The whisker lengths are determined by the BOXSTYLE= option in the PLOT statement. With BOXSTYLE=SCHEMATIC, the whiskers are drawn from the upper edge of the box to the largest observed value within the upper fence and from the lower edge of the box to the smallest observed value within the lower fence. The other whisker length available is BOXSTYLE=SKELETAL, which draws whiskers that extend out to the minimum and maximum data values.

The SYMBOL statement used with PROC GPLOT does have an interpolation option for specifying box plots with whiskers in percentile units, and allows the whiskers to be omitted. The examples below show basic and enhanced output from PROC GPLOT.

The following DATA step creates a test data set with some random data.

      data test;
        seed=238723;
        do group=1 to 3;
          do i=1 to 35;
            y=rannor(seed);
            output;
          end; 
        end;
        drop i;
        run;

It is convenient to define macro variables containing the desired percentile values. In these examples, whiskers will be drawn down to the 5^th percentile and up to the 95^th percentile.

      %let nn=5;
      %let mm=95;

The I=BOXnn interpolation option in the SYMBOL statement produces box-and-whisker plots in PROC GPLOT. You can specify the two additional digits nn from 00 to 25 to control the whisker length in percentile units. For example, the I=BOX05 option draws whiskers to the 5^th and 95^th percentiles.

      symbol i=box&nn bwidth=5 c=blue;
      axis1 offset=(15,15) minor=none;
      axis2 minor=none;
      title "Whiskers drawn to the &nn.th and &mm.th percentiles";
      proc gplot data=test;
        plot y*group / haxis=axis1 vaxis=axis2;
        run;
        quit;

The means for each box-and-whisker plot are not displayed by PROC GPLOT, and prior to SAS 9.2, neither are the outliers. If desired, you can compute and overlay these value as follows. These statements compute the mean of each group.

      proc means data=test noprint;
        by group;
        var y;
        output out=out(drop=_type_ _freq_) mean=mean;
        run;

This DATA step adds the group means to each observation in the raw data set.

      data test;
        merge test out;
        by group;
        run;

These statements create a box plot with the means plotted for each group.

      symbol i=box&nn bwidth=5 c=blue;
      symbol2 v=star c=blue h=1;
      symbol3 v=dot c=red h=1;
      axis1 offset=(15,15) minor=none;
      axis2 minor=none;
      title2 h=1 "Means added";
      proc gplot data=test;
        plot y*group mean*group / overlay haxis=axis1 vaxis=axis2;
        run;
        quit;

Similarly, you can compute and add the outliers to the plot.

      proc univariate data=test noprint;
        by group;
        var y;
        output out=out pctlpts=&nn &mm pctlpre=p;
        run;
      data test;
        merge test out;
        by group;
        if y<p&nn or y>p&mm then outlier=y;
        run;
   
      symbol i=box&nn bwidth=5 c=blue;
      symbol2 v=star c=blue h=1;
      symbol3 v=square c=red h=1;
      axis1 offset=(15,15) minor=none;
      axis2 minor=none;
      title2 h=1 'Means and Outliers added';
      proc gplot data=test;
        plot y*group mean*group outlier*group/ overlay haxis=axis1 vaxis=axis2;
        run;
        quit;

If you specify the I=BOX25 option in the SYMBOL statement, PROC GPLOT produces box plots with the whiskers omitted. The I=BOX25 option specifies that the whiskers be drawn to the 25^th and 75^th percentiles, which is equivalent to no whiskers.

      symbol i=box25 bwidth=5 c=blue;
      axis1 offset=(15,15) minor=none;
      axis2 minor=none;
      title "Whiskers omitted";
      proc gplot data=test;
        plot y*group / haxis=axis1 vaxis=axis2;
        run;
        quit;

Operating System and Release Information