Providing software solutions since 1976

• Log in
• Create profile
• Welcome
  [Log out]
• Edit profile

• Print  |
• Feedback  |
• Share

  • E-mail

  
  
  

  E-mail This Page

  Your Name:*
  Your E-mail:*
  Recipient E-mail:*
  Send a copy to me
  Personal Message:
  
  

  * indicates a required field

The CMH option in the TABLES statement of PROC FREQ is often used to obtain a test of the association between the row and column variables adjusted for the strata. Only asymptotic CMH tests, requiring large overall sample size, are available in PROC FREQ. For stratified 2 × 2 tables, an exact test can be obtained using the STRATA statement and PERM= option in PROC MULTTEST. PROC LOGISTIC can also provide an exact test when the EXACT and STRATA statements are specified. For stratified R × 2 tables in which the R-level predictor is ordinal, LOGISTIC and MULTTEST can both provide exact tests. If the predictor is nominal, an exact test can be obtained from LOGISTIC. Exact tests for stratified tables are not available when the response is multinomial.

Stratified 2 × 2 tables

In this example, we want to obtain a test of the association between migraine treatment and the response adjusted for the two genders (strata). The CMH option in PROC FREQ provides an asymptotic test of the association.

      data Migraine;
         input Gender $ Treatment $ Response $ Count @@;
         y=(response="Better");
         datalines;
      female Active  Better 16   female Active  Same 11
      female Placebo Better  5   female Placebo Same 20
      male   Active  Better 12   male   Active  Same 16
      male   Placebo Better  7   male   Placebo Same 19
      ;

      proc freq data=Migraine;
         weight Count;
         tables Gender*Treatment*Response / cmh noprint;
         run;

The same asymptotic test is provided as the score test in PROC LOGISTIC when a STRATA statement is specified. By also including an EXACT statement, an exact score test of the association is given.

      proc logistic data=Migraine;
         class treatment / param=ref;
         freq count;
         model response=treatment;
         strata gender;
         exact treatment;
         run;

The exact test can also be obtained from PROC MULTEST by specifying the STRATA statement, and the PERM= option to the Cochran-Armitage (CA) test. The value of the PERM= option should exceed the total in any stratum. The Model Information table displayed by MULTTEST should indicate Exact permutation distribution used: Everywhere. Note that MULTTEST requires a numerical response with the value 1 indicating the event of interest and value 0 indicating a nonevent. The variable Y was created in the DATA step above for this purpose.

      proc multtest data=Migraine;
         class treatment;
         freq count;
         test ca(y / perm=100);
         strata gender;
         run;

Stratified R × 2 tables

In this example, from Luta, et. al. (1998) and analyzed by Stokes et. al. (2000), each of eight animals (ANIMAL) undergoes several of four possible treatments (ORDTREAT) and it is observed whether a particular cardiovascular event (RESPONSE) occurs. The treatments are considered to have a logical ordering and are coded in proper increasing order. The first CMH statistic provided by the CMH option in PROC FREQ tests the linear association of the ordinal treatments with the response.

      data animal;
         input animal treatment $ response $ @@; 
         y=(response="yes");
         if treatment='S' then delete;
         else if treatment='C'  then ordtreat=1;
         else if treatment='DA' then ordtreat=2;
         else if treatment='D1' then ordtreat=3;
         else if treatment='D2' then ordtreat=4;
         datalines; 
      1 S no  1 C  no  1 C  no  1 D2 yes 1 D1 yes
      2 S no  2 D2 yes 2 C  no  2 D1 yes 
      3 S no  3 C  yes 3 D1 yes 3 DA no  3 C  no 
      4 S no  4 C  no  4 D1 yes 4 DA no  4 C  no 
      5 S yes 5 C  no  5 DA no  5 D1 no  5 C  no 
      6 S no  6 C  no  6 D1 yes 6 DA no  6 C  no 
      7 S no  7 C  no  7 D1 yes 7 DA no  7 C  no 
      8 S yes 8 C  yes 8 D1 yes   
      ;
      
      proc freq data=animal; 
         table animal*ordtreat*response / cmh noprint;
         run;

As in the stratified 2 × 2 case, PROC LOGISTIC with the STRATA statement provides the asymptotic test from PROC FREQ as the score test. By including the EXACT statement, an exact score test is also provided.

      proc logistic data=animal;
         strata animal;
         model response(event="yes") = ordtreat; 
         exact ordtreat; 
         run; 

Again, using a properly coded response (Y), the STRATA statement and PERM= option in PROC MULTTEST allow you to get an exact test in this situation. The CONTRAST statement ensures that the numeric scores assigned to the levels of ORDTREAT are used in computing the test.

      proc multtest data=animal;
         class ordtreat;
         test ca(y / perm=5);
         strata animal;
         contrast 'ordtreat' 1 2 3 4;
         run;

If the treatments had no logical ordering, or if it is desired to ignore their ordinality, the asymptotic test comparing the treatments is available as the second CMH statistic from PROC FREQ, labeled "Row Mean Scores Differ". By including ORDTREAT in the CLASS statement, PROC LOGISTIC also provides the asymptotic score test, and if the EXACT statement is specified an exact score test is also obtained. The asymptotic analysis results in a singular information matrix making those results unusable, but the asymptotic and exact score tests can be used. Note that by adding the EXACTONLY option in the PROC LOGISTIC statement, the asymptotic analysis could be suppressed which prevents the warning messages about singularity caused by that analysis.

      proc logistic data=animal;
         strata animal;
         class ordtreat / param=ref;
         model response(event="yes") = ordtreat; 
         exact ordtreat; 
         run; 

_____

Dmitrienko, A., Molenberghs, G., Chuang-Stein, C., and Offen, W. (2005), Analysis of Clinical Trials Using SAS: A Practical Guide, Cary, NC: SAS Institute.

Luta, G., Koch, G.G., Cascio, W.E., and Smith, W.T. (1998), "An application of methods for clustered binary responses to a cardiovascular study with small sample size," Journal of Biopharmaceutical Statistics, 8, 87-102.

Stokes, M.E., Davis, C.S., and Koch, G.G. (2000), Categorical Data Analysis Using the SAS System, Second Edition, Cary, NC: SAS Institute Inc.

Operating System and Release Information