25498 - Draw a circle of stars using PROC GANNO

Sample 25498: Draw a circle of stars using PROC GANNO

This sample demonstrates how to use an Annotate data set with PROC GANNO to draw a flag that is composed of a rectangle and four stars.

The graphics output in the Results tab was produced using SAS® 9.2. Submitting the sample code with releases of SAS prior to SAS 9.2 might produce different results.

 /* Set the graphics environment */
goptions reset=all cback=white border htitle=12pt htext=10pt;  

data flag;
   length function color $ 8 style text $ 30;
   retain xsys ysys hsys '3';

      /* Draw the frame */
   function='frame'; output;

      /* Define the footnote */
   function='label'; x=85; y=3; 
   text='Sample Annotate Output';
      style="'Albany AMT'"; size=3; position='5'; output;

      /* Define the title */
   x=50; y=90; text='Flag of Micronesia';
      style="'Albany AMT/bold'"; size=6; output;

     /* Draw the background */
   function='move'; x=20; y=30; output;
   function='bar'; x=80; y=80; color='CX7C95CA';
      line=3; style='solid'; output;

     /* Draw the circle of stars */
   do star_ang=0 to 270 by 90;
      function='piecntr'; x=50; y=55; size=15; output;
      function='piexy'; size=1; angle=star_ang; output;
      function='cntl2txt'; output;
      function='symbol'; style='marker'; text='V';
         angle=0; color='white'; size=10; x=.; y=.;
         output;
   end;
run;

 /* Generate the output from */
 /* the Annotate data set    */
proc ganno annotate=flag;
run;
quit;

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Date Modified:	2005-07-20 03:02:43
Date Created:	2005-05-23 14:11:29

Product Family	Product	Host	SAS Release
Product Family	Product	Host	Starting	Ending
SAS System	SAS/GRAPH	z/OS	9.1 TS1M0
		Microsoft® Windows® for 64-Bit Itanium-based Systems	9.1 TS1M0
		Microsoft Windows Server 2003 Datacenter 64-bit Edition	9.1 TS1M0
		Microsoft Windows Server 2003 Enterprise 64-bit Edition	9.1 TS1M0
		Microsoft Windows 2000 Advanced Server	9.1 TS1M0
		Microsoft Windows 2000 Datacenter Server	9.1 TS1M0
		Microsoft Windows 2000 Server	9.1 TS1M0
		Microsoft Windows 2000 Professional	9.1 TS1M0
		Microsoft Windows NT Workstation	9.1 TS1M0
		Microsoft Windows Server 2003 Datacenter Edition	9.1 TS1M0
		Microsoft Windows Server 2003 Enterprise Edition	9.1 TS1M0
		Microsoft Windows Server 2003 Standard Edition	9.1 TS1M0
		Microsoft Windows XP Professional	9.1 TS1M0
		64-bit Enabled AIX	9.1 TS1M0
		64-bit Enabled HP-UX	9.1 TS1M0
		64-bit Enabled Solaris	9.1 TS1M0
		HP-UX IPF	9.1 TS1M0
		Linux	9.1 TS1M0
		OpenVMS Alpha	9.1 TS1M0
		Tru64 UNIX	9.1 TS1M0

Support

Sample 25498: Draw a circle of stars using PROC GANNO

Operating System and Release Information