• Print |
• E-mail  |
• Bookmark

/*+-------------------------------------------------------------+
  |          S A S   S A M P L E   L I B R A R Y                |
  |                                                             |
  |    NAME: GTGDEFIN                                           |
  |   TITLE: GTGDEFIN-Default G3GRID Interpolation Method       |
  | PRODUCT: GRAPH                                              |
  |  SYSTEM: ALL                                                |
  |    KEYS: GRAPHICS GOPTIONS G3GRID G3D                       |
  |   PROCS: G3GRID G3D                                         |
  |    DATA: INTERNAL                                           |
  |                                                             |
  | SUPPORT: GRAPHICS STAFF              UPDATE:                |
  |     REF: SAS/GRAPH REFERENCE GUIDE                          |
  +-------------------------------------------------------------+*/

  /* Set the graphics environment */
goptions reset=all gunit=pct border cback=white
         colors=(blue black green red)
         ftext=swiss ftitle=swissb htitle=6 htext=3;

  /* Create data set WORK.NUMS using  */
  /* a set of randomly sampled points */
data nums;
   keep x y z;
   do i=1 to 30;
      x=10*ranuni(33)-5;
      y=10*ranuni(35)-5;
      z=sin(sqrt(x*x+y*y));
      output;
   end;
run;

  /* Define title and footnote for graph */
title 'Scatter Plot of NUMS Data Set';
footnote j=r 'GTGDEFIN(a)';

  /* Generate the scatter plot */
proc g3d data=nums;
   scatter y*x=z;
run;

  /* Process points with PROC G3GRID */
proc g3grid data=nums out=default;
   grid y*x=z / axis1=-5 to 5 by .5
                axis2=-5 to 5 by .5;
run;

  /* Define title and footnote for graph */
title 'Surface Plot After Default Interpolation';
footnote j=r 'GTGDEFIN(b)';

  /* Show the surface graph */
proc g3d data=default;
   plot y*x=z;
run;
quit;

Operating System and Release Information