• Print |
• E-mail  |
• Bookmark

 /*+-------------------------------------------------------------+
   |          S A S   S A M P L E   L I B R A R Y                |
   |                                                             |
   |    NAME: GRMAFRIC                                           |
   |   TITLE: GRMAFRIC-Creating an Outline Map of Africa         |
   | PRODUCT: GRAPH                                              |
   |  SYSTEM: ALL                                                |
   |    KEYS: GRAPHICS GOPTIONS GMAP GREMOVE MAPS PATTERN        |
   |   PROCS: GMAP GREMOVE                                       |
   |    DATA: EXTERNAL                                           |
   |                                                             |
   | SUPPORT: GRAPHICS STAFF              UPDATE:                |
   |     REF: SAS/GRAPH REFERENCE GUIDE                          |
   |    MISC: EDIT AND UNCOMMENT THE LIBNAME STATEMENTS          |
   |          IF THE LIBREFS HAVE NOT BEEN DEFINED.              |
   |                                                             |
   +-------------------------------------------------------------+*/

   /* Define the libref maps */
*libname maps 'SAS-data-library';

   /* Set the graphics environment */
goptions reset=all gunit=pct border cback=white
         colors=(black blue green red)
         ftext=swiss htitle=6 htext=3;

   /* Create data set NEWAF */
data newaf;
   set maps.africa;
   region=1;
run;

   /* Remove the unit areas from the AFRICA data set */
proc gremove data=newaf out=africa;
   by region;
   id id;
run;

   /* Define title and footnote */
title 'Africa with Boundaries';
footnote j=r 'GRMAFRIC(a) ';

   /* Define pattern characteristics */
pattern value=mempty r=50 color=blue;

   /* Display the original map */
proc gmap map=maps.africa data=maps.africa all;
   id id;
   choro id / nolegend;
run;

   /* Define new title and footnote for map */
title 'Africa without Boundaries';
footnote j=r 'GRMAFRIC(b) ';

   /* Display the map */
proc gmap data=africa map=africa;
   id region;
   choro region / nolegend;
run;
quit;

Operating System and Release Information