Sample 25590: Creating a common title and footnote for PROC GREPLAY output
This sample creates a common title and footnote for PROC GREPLAY output.
This sample is from the "SAS/GRAPH Software: Reference, Version 8", Volume 2, Chapter 26.
For additional information on the sample refer to this book.
/*+-------------------------------------------------------------+
| S A S S A M P L E L I B R A R Y |
| |
| NAME: GRERGOT1 |
| TITLE: GRERGOT1-Replaying Graphics Output in a Template |
| PRODUCT: GRAPH |
| SYSTEM: ALL |
| KEYS: GRAPHICS GOPTIONS GREPLAY GSLIDE |
| PROCS: GREPLAY GSLIDE |
| DATA: INTERNAL |
| |
| SUPPORT: GRAPHICS STAFF UPDATE: |
| REF: SAS/GRAPH REFERENCE GUIDE |
| MISC: THIS PROGRAM CREATES PERMANENT GRAPHICS CATALOG. |
+-------------------------------------------------------------+*/
/* Set the graphics environment */
/* Suppress the graphics display */
/* Adjust hsize and vsize for template panels */
goptions gunit=pct border
cback=white colors=(black blue red green)
ftext=swiss htitle=8 htext=5
hsize=4in vsize=3.8in;
/* Generate some graphs */
proc gslide gout=grafcat;
title c=red 'Graph Number 1';
footnote h=3 j=r 'GRERGOT1(a) ';
run;
title 'Graph Number 2';
footnote h=3 j=r 'GRERGOT1(b) ';
run;
title 'Graph Number 3';
footnote h=3 j=r 'GRERGOT1(c) ';
run;
/* Reset hsize and vsize to default values */
goptions hsize=0in vsize=0in;
/* Generate one more graph */
proc gslide gout=grafcat;
title 'Common Title';
footnote 'Common Footnote';
run;
/* Start the GREPLAY procedure */
proc greplay igout=grafcat
tc=tempcat nofs;
/* Define a template */
tdef newtemp des='Five panel template'
/* Define panel 1 */
1/llx=0 lly=10
ulx=0 uly=50
urx=50 ury=50
lrx=50 lry=10
color=blue
/* Define panel 2 */
2/llx=0 lly=50
ulx=0 uly=90
urx=50 ury=90
lrx=50 lry=50
color=red
/* Define panel 3 */
3/llx=50 lly=50
ulx=50 uly=90
urx=100 ury=90
lrx=100 lry=50
color=green
/* Define panel 4 */
4/llx=50 lly=10
ulx=50 uly=50
urx=100 ury=50
lrx=100 lry=10
color=cyan
/* Define panel 5 */
5/llx=0 lly=0
ulx=0 uly=100
urx=100 ury=100
lrx=100 lry=0
color=lipk;
/* Assign current template */
template newtemp;
/* List contents of current template */
list template;
/* Replay three graphs into template */
treplay 1:gslide
2:gslide1
3:gslide2
5:gslide3;
quit;
This sample creates a template and uses the TREPLAY statement to replay the graphs into the template.
| Type: | Sample |
| Topic: | SAS Reference ==> Procedures ==> GREPLAY
|
| Date Modified: | 2005-07-29 03:02:39 |
| Date Created: | 2005-05-23 14:17:31 |
Operating System and Release Information
| SAS System | SAS/GRAPH | All | 8 TS M0 | n/a |
