25582 - Plotting with different scales of values using PROC GPLOT

Sample 25582: Plotting with different scales of values using PROC GPLOT

This sample is from the "SAS/GRAPH Software: Reference, Version 8", Volume 2, Chapter 21. For additional information on the sample refer to this book.

 /*+-------------------------------------------------------------+
   |          S A S   S A M P L E   L I B R A R Y                |
   |                                                             |
   |    NAME: GPLSCVL1                                           |
   |   TITLE: GPLSCVL1-Plotting with Different Scales of Values  |
   | PRODUCT: GRAPH                                              |
   |  SYSTEM: ALL                                                |
   |    KEYS: GRAPHICS GOPTIONS GPLOT AXIS SYMBOL                |
   |   PROCS: GPLOT                                              |
   |    DATA: INTERNAL                                           |
   |                                                             |
   | SUPPORT: GRAPHICS STAFF              UPDATE:                |
   |     REF: SAS/GRAPH REFERENCE GUIDE                          |
   |    MISC: THIS PLOT USES INTERPOLATION.                      |
   +-------------------------------------------------------------+*/


   /* Set the graphics environment */
goptions reset=all gunit=pct border cback=white
         colors=(black blue green red)
         ftext=swiss ftitle=swissb htitle=6 htext=3;

   /* Create the data set MINNTEMP */
data minntemp;
   input @10 month
         @23 f2;    /* fahrenheit temperature for Minneapolis */

      /* Calculate centigrade temperature */
      /* for Minneapolis                  */
   c2=(f2-32)/1.8;
   output;
   datalines;
01JAN83  1    1   40.5  12.2  52.1
01FEB83  2    1   42.2  16.5  55.1
01MAR83  3    2   49.2  28.3  59.7
01APR83  4    2   59.5  45.1  67.7
01MAY83  5    2   67.4  57.1  76.3
01JUN83  6    3   74.4  66.9  84.6
01JUL83  7    3   77.5  71.9  91.2
01AUG83  8    3   76.5  70.2  89.1
01SEP83  9    4   70.6  60.0  83.8
01OCT83  10   4   60.2  50.0  72.2
01NOV83  11   4   50.0  32.4  59.8
01DEC83  12   1   41.2  18.6  52.5
;

   /* Define title and footnotes */
title1 'Average Monthly Temp for Minneapolis';
footnote1 j=l ' Source: 1984 American Express';
footnote2 j=l '         Appointment Book'
          j=r 'GPLSCVL1 ';

   /* Define symbol characteristics */
symbol1 interpol=needle ci=blue cv=red width=3 value=star
        height=3;
symbol2 interpol=none value=none;

   /* Define axis characteristics */
axis1 label=none
      value=(h=2.5 'JAN' 'FEB' 'MAR' 'APR' 'MAY' 'JUN'
                 'JUL' 'AUG' 'SEP' 'OCT' 'NOV' 'DEC')
      order=(1 to 12 by 1)
      offset=(2)
      width=3;
axis2 label=(h=3 'Degrees' justify=right ' Centigrade')
      order=(-20 to 30 by 10)
      width=3
      value=(h=3);
axis3 label=(h=3 'Degrees' justify=left 'Fahrenheit')
      order=(-4 to 86 by 18)
      width=3
      value=(h=3);

   /* Generate a plot with a second vertical axis */
proc gplot data= minntemp;
   plot c2*month / frame
                   caxis=red
                   haxis=axis1 hminor=0
                   vaxis=axis2 vminor=1;
   plot2 f2*month / caxis=red
                    vaxis=axis3 vminor=1;
run;
quit;

Type:	Sample
Topic:	SAS Reference ==> Procedures ==> GPLOT

Date Modified:	2005-08-27 03:03:27
Date Created:	2005-05-23 14:17:00

Product Family	Product	Host	SAS Release
			Starting	Ending
SAS System	SAS/GRAPH	All	8 TS M0	n/a

Knowledge Base

Sample 25582: Plotting with different scales of values using PROC GPLOT

Operating System and Release Information