• Print |
• E-mail  |
• Bookmark

 /*+-------------------------------------------------------------+
   |          S A S   S A M P L E   L I B R A R Y                |
   |                                                             |
   |    NAME: GPJDEFLT                                           |
   |   TITLE: GPJDEFLT-Using Default Projection Specs in a Map   |
   | PRODUCT: GRAPH                                              |
   |  SYSTEM: ALL                                                |
   |    KEYS: GRAPHICS GOPTIONS GMAP GPROJECT MAPS PATTERN       |
   |   PROCS: GMAP GPROJECT                                      |
   |    DATA: EXTERNAL                                           |
   |                                                             |
   | SUPPORT: GRAPHICS STAFF              UPDATE:                |
   |     REF: SAS/GRAPH REFERENCE GUIDE                          |
   |    MISC: THIS MAP HAS A LIBNAME ALLOCATION TO MAP DATASETS. |
   |          EDIT AND UNCOMMENT THE LIBNAME STATEMENTS          |
   |          IF THE LIBREFS HAVE NOT BEEN DEFINED.              |
   +-------------------------------------------------------------+*/

   /* Assign the libref MAPS */
*libname maps 'SAS-data-library';

   /* Set the graphics environment */
goptions reset=all gunit=pct border cback=white
         colors=(black blue green red)
         ftext=swiss htitle=6 htext=3;

   /* Create reduced continental U.S. map data set */
   /* and remove Alaska, Hawaii, and Puerto Rico   */
data us48;
   set maps.states;
   if state ne 2 and state ne 15 and state ne 72;
   if density<3;
run;

   /* Define title and footnote for unprojected map */
title 'United States Map';
footnote j=r 'GPJDEFLT(a) ';

   /* Define pattern characteristics */
pattern value=mempty repeat=50 color=blue;

   /* Show unprojected map */
proc gmap map=us48 data=us48 all;
   id state;
   choro state / nolegend;
run;

   /* Project map data set using all default criteria */
proc gproject data=us48 out=us48proj;
   id state;
run;

   /* Define footnote for projected map */
footnote j=r 'GPJDEFLT(b) ';

   /* Show projected map */
proc gmap map=us48proj data=us48proj all;
   id state;
   choro state / nolegend;
run;
quit;

Operating System and Release Information