• Print |
• E-mail  |
• Bookmark

 
 /*+------------------------------------------------------+
   |          S A S   S A M P L E   L I B R A R Y         |
   |                                                      |
   |    NAME: GCHBRGRP                                    |
   |   TITLE: GCHBRGRP-Subgrouping a 3D Vertical Bar Chart|
   | PRODUCT: GRAPH                                       |
   |  SYSTEM: ALL                                         |
   |    KEYS: GRAPHICS GCHART AXIS PATTERN LEGEND         |
   |   PROCS: GCHART                                      |
   |    DATA: INTERNAL                                    |
   |                                                      |
   | SUPPORT: GRAPHICS STAFF       UPDATE:                |
   |     REF: SAS/GRAPH REFERENCE GUIDE                   |
   +------------------------------------------------------+*/

   /* Set the graphics environment */
goptions reset=all gunit=pct border cback=white
         colors=(black red green blue) ftitle=swissb
         ftext=swiss htitle=6 htext=3
         offshadow=(1.5,1.5);

   /* Create data set TOTALS */
data totals;
   length Dept $ 7 Site $ 8;
   input Dept Site Quarter Sales;
   datalines;
Parts   Sydney  1 4043.97
Parts   Atlanta 1 6225.26
Parts   Paris   1 3543.97
Repairs Sydney  1 5592.82
Repairs Atlanta 1 9210.21
Repairs Paris   1 8591.98
Tools   Sydney  1 1775.74
Tools   Atlanta 1 2424.19
Tools   Paris   1 5914.25
Parts   Sydney  2 3723.44
Parts   Atlanta 2 11595.07
Parts   Paris   2 9558.29
Repairs Sydney  2 5505.31
Repairs Atlanta 2 4589.59
Repairs Paris   2 7538.56
Tools   Sydney  2 2945.17
Tools   Atlanta 2 1903.99
Tools   Paris   2 7868.34
Parts   Sydney  3 8437.96
Parts   Atlanta 3 6847.91
Parts   Paris   3 6789.85
Repairs Sydney  3 4426.46
Repairs Atlanta 3 5011.66
Repairs Paris   3 6510.38
Tools   Sydney  3 3767.10
Tools   Atlanta 3 3048.52
Tools   Paris   3 9017.96
Parts   Sydney  4 6065.57
Parts   Atlanta 4 9388.51
Parts   Paris   4 8509.08
Repairs Sydney  4 3012.99
Repairs Atlanta 4 2088.30
Repairs Paris   4 5530.37
Tools   Sydney  4 3817.36
Tools   Atlanta 4 4354.18
Tools   Paris   4 6511.70
;

   /* Define title and footnote for chart */
title 'Total Sales by Site';
footnote h=3 j=r 'GCHBRGRP ';

   /* Define axis characteristics */
axis1 label=none
      origin=(24,);
axis2 label=none
      order=(0 to 100000 by 20000)
      minor=(number=1)
      offset=(,0);

   /* Optional: remove vertical axis */
axis3 noplane label=none value=none style=0 major=none minor=none;

   /* Define legend characteristics */
legend1 label=none
        shape=bar(3,3)
        cborder=black
        cblock=gray
        origin=(24,);

   /* Define pattern characteristics */
pattern1 color=lipk;
pattern2 color=cyan;
pattern3 color=lime;

   /* Generate horizontal bar chart */
proc gchart data=totals;
   format quarter roman.;
   format sales dollar8.;
   vbar3d site / sumvar=sales
                 subgroup=dept
                 inside=subpct
                 outside=sum
                 width=9
                 space=4
                 cframe=gray
                 maxis=axis1
                 raxis=axis2
                 coutline=black
                 legend=legend1;
run;
quit;

Operating System and Release Information