25509 - Grouping & subgrouping a block chart using PROC GCHART

Sample 25509: Grouping & subgrouping a block chart using PROC GCHART

This sample is from the "SAS/GRAPH Software: Reference, Version 8", Volume 1, Chapter 13. For additional information on the sample refer to this book.

 /*+--------------------------------------------------------+
   |          S A S   S A M P L E   L I B R A R Y           |
   |                                                        |
   |    NAME: GCHBKGRP                                      |
   |   TITLE: GCHBKGRP-Grouping & Subgrouping a Block Chart |
   | PRODUCT: GRAPH                                         |
   |  SYSTEM: ALL                                           |
   |    KEYS: GRAPHICS GCHART LEGEND                        |
   |   PROCS: GCHART                                        |
   |    DATA: INTERNAL                                      |
   |                                                        |
   | SUPPORT: GRAPHICS STAFF        UPDATE:                 |
   |     REF: SAS/GRAPH REFERENCE GUIDE                     |
   +--------------------------------------------------------+*/

   /* Set the graphics environment */
goptions reset=all gunit=pct border cback=white
         colors=(blue green red) ctext=black
         ftitle=swissb ftext=swiss htitle=4 htext=3;

   /* Create data set TOTALS */
data totals;
   length Dept $ 7 Site $ 8;
   input Dept Site Quarter Sales;
   datalines;
Parts   Sydney  1 4043.97
Parts   Atlanta 1 6225.26
Parts   Paris   1 3543.97
Repairs Sydney  1 5592.82
Repairs Atlanta 1 9210.21
Repairs Paris   1 8591.98
Tools   Sydney  1 1775.74
Tools   Atlanta 1 2424.19
Tools   Paris   1 5914.25
Parts   Sydney  2 3723.44
Parts   Atlanta 2 11595.07
Parts   Paris   2 9558.29
Repairs Sydney  2 5505.31
Repairs Atlanta 2 4589.59
Repairs Paris   2 7538.56
Tools   Sydney  2 2945.17
Tools   Atlanta 2 1903.99
Tools   Paris   2 7868.34
Parts   Sydney  3 8437.96
Parts   Atlanta 3 6847.91
Parts   Paris   3 6789.85
Repairs Sydney  3 4426.46
Repairs Atlanta 3 5011.66
Repairs Paris   3 6510.38
Tools   Sydney  3 3767.10
Tools   Atlanta 3 3048.52
Tools   Paris   3 9017.96
Parts   Sydney  4 6065.57
Parts   Atlanta 4 9388.51
Parts   Paris   4 8509.08
Repairs Sydney  4 3012.99
Repairs Atlanta 4 2088.30
Repairs Paris   4 5530.37
Tools   Sydney  4 3817.36
Tools   Atlanta 4 4354.18
Tools   Paris   4 6511.70
;

   /* Define title and footnote for chart */
title1 'Average Sales by Department';
footnote1 h=3 j=r 'GCHBKGRP ';

   /* Define legend characteristics */
legend1 cborder=black
        label=('Quarter:')
        position=(middle left outside)
        mode=protect
        across=1
        ;

   /* Generate block chart */
proc gchart data=totals;
   format quarter roman.;
   format sales dollar8.;
   label site='00'x dept='00'x;
   block site / sumvar=sales
                type=mean
                midpoints='Sydney' 'Atlanta'
                group=dept
                subgroup=quarter
                legend=legend1
                noheading
                coutline=black
                caxis=black;
run;
quit;

Type:	Sample
Topic:	SAS Reference ==> Procedures ==> GCHART Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Types ==> Charts ==> Block

Date Modified:	2005-07-23 03:02:37
Date Created:	2005-05-23 14:12:12

Product Family	Product	Host	SAS Release
			Starting	Ending
SAS System	SAS/GRAPH	All	8 TS M0	n/a

Knowledge Base

Sample 25509: Grouping & subgrouping a block chart using PROC GCHART

Operating System and Release Information