25506 - Ordering axis tick marks with SAS datetime values using PROC GPLOT

Sample 25506: Ordering axis tick marks with SAS datetime values using PROC GPLOT

This sample is from the "SAS/GRAPH Software: Reference, Version 8", Volume 1, Chapter 8. For additional information on the sample refer to this book.

 /*+--------------------------------------------------------------+
   |          S A S   S A M P L E   L I B R A R Y                 |
   |                                                              |
   |    NAME: GAXTMDV1                                            |
   |   TITLE: GAXTMDV1-Ordering Axis Tick Marks w/Datetime Values |
   | PRODUCT: GRAPH                                               |
   |  SYSTEM: ALL                                                 |
   |    KEYS: GRAPHICS AXIS SYMBOL GPLOT                          |
   |   PROCS: GPLOT                                               |
   |    DATA: INTERNAL                                            |
   |                                                              |
   | SUPPORT: GRAPHICS STAFF              UPDATE:                 |
   |     REF: SAS/GRAPH REFERENCE GUIDE                           |
   +--------------------------------------------------------------+*/

   /* Set the graphics environment */
goptions reset=all gunit=pct border cback=white
         colors=(black blue green red)
         ftitle=swissb ftext=swiss htitle=6 htext=2;

   /* Create the data set DOWHLC */
data dowhlc;
   input date date9. high low close;
   format date date9.;
   datalines;
02JAN1997   6511.38  6318.96  6442.49
03JAN1997   6586.42  6437.10  6544.09
06JAN1997   6647.22  6508.30  6567.18
07JAN1997   6621.82  6481.75  6600.66
08JAN1997   6650.30  6509.84  6549.48
09JAN1997   6677.24  6520.23  6625.67
10JAN1997   6725.35  6530.62  6703.79
13JAN1997   6773.45  6647.99  6709.18
14JAN1997   6816.17  6689.94  6762.29
15JAN1997   6800.77  6669.93  6726.88
16JAN1997   6818.47  6688.40  6765.37
17JAN1997   6863.88  6732.66  6833.10
20JAN1997   6839.13  6777.30  6843.87
21JAN1997   6934.69  6771.14  6883.90
22JAN1997   6913.14  6801.16  6850.03
23JAN1997   6953.55  6724.19  6755.75
24JAN1997   6798.08  6629.91  6696.48
27JAN1997   6748.82  6598.73  6660.69
28JAN1997   6823.48  6612.20  6656.08
29JAN1997   6673.39  6627.98  6740.74
30JAN1997   6845.03  6719.96  6823.86
31JAN1997   6912.37  6769.99  6813.09
;

data dowhlc2;
   set dowhlc;
   drop high low close;
   dow=high; output;
   dow=low; output;
   dow=close; output;
run;

   /* Define titles and footnote */
title1 'Dow Jones High-Low-Close';
title2 'January, 1997';
footnote height=3 justify=right 'GAXTMDV1 ';

   /* Define symbol characteristics */
symbol interpol=hiloctj
       cv=red
       ci=blue
       width=2;

   /* Modify horizontal axis */
axis1 order=('30DEC1996'd to '03FEB1997'd by week)
      offset=(3,3)
      color=blue
      label=none
      major=(height=3 width=2)
      minor=(number=6 color=red height=2 width=1)
      width=3;

   /* Modify vertical axis */
axis2 color=blue
      label=none
      major=(height=3)
      minor=(number=4 color=red height=1)
      offset=(2,2);

   /* Generate plot and assign AXIS definitions */
proc gplot data=dowhlc2;
   plot dow*date / haxis=axis1
                   vaxis=axis2;
run;
quit;

Type:	Sample
Topic:	Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Elements ==> Labels Query and Reporting ==> Creating Reports ==> Graphical ==> Graph Elements ==> Axis SAS Reference ==> Procedures ==> GPLOT

Date Modified:	2005-07-23 03:02:37
Date Created:	2005-05-23 14:12:00

Product Family	Product	Host	SAS Release
			Starting	Ending
SAS System	SAS/GRAPH	All	8 TS M0	n/a

Knowledge Base

Sample 25506: Ordering axis tick marks with SAS datetime values using PROC GPLOT

Operating System and Release Information