This example demonstrates how a SAS program running on z/OS can write output in HTML format directly to a UNIX file. The key is the FTP access method:

• the FILENAME statement specifies that myfile is written with the FTP access method
  
• the ODS statement opens the HTML destination and directs the procedure output to myfile

The output generated in this example is an HTML file, but it could have been any type of output supported by the ODS statement.

To run this example, you need to provide values for the UNIX filename, target directory, host and user. These parameters are highlighted in red. The option prompt generates a prompt for the UNIX password. You can substitute pass='xxxx' for prompt to specify the password explicitly.
 

/* --------------------------------------------------------------------

FILENAME Options

--------------------------------------------------------------------- */

filename myfile ftp
'filename.html'
cd='/u/targetdir/public_html'
host='unxhost.unx.sas.com'
user='unxusr'
prompt
rcmd='site umask 022'
recfm=s
debug;

ods listing close;

/* --------------------------------------------------------------------

ODS Options

--------------------------------------------------------------------- */

ods html body=myfile
style=bluebg
trantab=ascii;

proc print data=sashelp.class double;
where age = 12;
title 'Height and Weight for 12 Year Olds';
run;

quit;

ods html close;

ods listing;

ods path sasuser templat(update) sashelp.tmplmst(read);

proc template;
define style bluebg;
parent = styles.default;
replace color_list /

'fgB2' = cx0066AA
'fgB1' = cx004488
'fgA4' = cxAAFFAA
'bgA4' = cx880000
'bgA3' = cxD3D3D3
'fgA2' = cx0033AA
'bgA2' = cxB0B0B0
'fgA1' = cx000000
'bgA1' = cxF0F0F0
'fgA' = cx002288

/* changed from cxE0E0E0 */

'bgA' = cx9BBCFF;

end;

run;