• Print |
• E-mail  |
• Bookmark

/* Use the Annotate Facility to draw  one std of    */
/* the mean on a vbar chart.  PROC MEANS is used to */
/* get the necessary statistics to be used by the   */
/* annotate data step.                              */

goptions reset=all border;

data a;
  input mid_var $ resp_var;
  datalines;
AAA 5
AAA 4
AAA 7
BBB 7
BBB 6
BBB 9
CCC 4
CCC 3
CCC 6
DDD 5
DDD 4
DDD 7
;

proc means mean std data=a noprint;
  by mid_var;
  output out=b mean=mean std=std;
run;

data anno;
  length color function $8;
  retain xsys ysys '2' hsys '4' when 'a' color 'red' size 1;
  set b;

  /* Lower tick */
  function='move'; xsys='2'; ysys='2'; midpoint=mid_var; y=mean-std; output;
  function='draw'; xsys='7'; ysys='2'; x=-2; y=mean-std;  output;
  function='draw'; xsys='7'; ysys='2'; x=+4; y=mean-std;  output;

  /* Upper tick */
  function='move'; xsys='2'; ysys='2'; midpoint=mid_var; y=mean+std; output;
  function='draw'; xsys='7'; ysys='2'; x=-2; y=mean+std;  output;
  function='draw'; xsys='7'; ysys='2'; x=+4; y=mean+std;  output;

  /* Join upper and lower */
  function='move'; xsys='2'; ysys='2'; midpoint=mid_var; y=mean-std;  output;
  function='draw'; xsys='2'; ysys='2'; midpoint=mid_var; y=mean+std;  output;

run;

pattern1 v=empty c=blue;
axis1 order=(0 to 10 by 5);
title1 ' One Std of Mean';

proc gchart data=a;
  vbar mid_var / anno=anno raxis=axis1 type=mean sumvar=resp_var;
run;
quit;

Operating System and Release Information