When the hash object is created and the DATASET: argument tag is used, the data variables must exist in the input data set.

If you have an additional variable that you want to specify in a DEFINEKEY or DEFINEDATA method, you can either

a) Load the data set into the hash table manually using the ADD() method rather than with the DATASET: argument tag. For example:

     data new;
       if _n_ = 1 then do;
         if 0 then set sashelp.class;  /* Add variables from the view */
                                       /* to the PDV for WORK.NEW     */
         declare hash ht();
         ht.definekey ('name','teacher');
         ht.definedata('name','teacher','age');
         ht.definedone();
       end;

       do while(not last);
         set sashelp.class end=last;
	 teacher=' ';
	 rc=ht.add();
       end;
       ...;
     run;

OR

b) Create a view using the existing data set plus the new variable. Use the view in the DATASET: argument tag. For example:

     /* Create a view of the desired data set plus the additional variable */
     data class_vw/view=class_vw;
       retain teacher ' ';
       set sashelp.class(keep = name age);
     run;

     data new;
       if _n_ = 1 then do;
         if 0 then set class_vw;  /* Add variables from the view to */
                                  /* the PDV for WORK.NEW           */
         declare hash ht(dataset: 'class_vw');
         ht.definekey ('name','teacher');
         ht.definedata('name','teacher','age');
         ht.definedone();
       end;
       ...
     run;

Operating System and Release Information