Providing software solutions since 1976

• Log in
• Create profile
• Welcome
  [Log out]
• Edit profile

• Print  |
• Feedback  |
• Share

  • E-mail

  
  
  

  E-mail This Page

  Your Name:*
  Your E-mail:*
  Recipient E-mail:*
  Send a copy to me
  Personal Message:
  
  

  * indicates a required field

A single test of whether any of the group proportions differs from the overall proportion is given by the CHISQ option in PROC FREQ when applied to a G×2 or 2×G table of your data (the two columns or rows being positive and negative response). Significant results indicate that at least one proportion differs from the overall proportion. Tests of each group versus overall can be done in PROC MULTTEST by using the CA test and a set of CONTRAST statements, or in PROC LOGISTIC. PROC MULTTEST additionally enables you to adjust the p-values for the fact that multiple testing is done. The tests from PROC LOGISTIC can be adjusted by importing them into PROC MULTTEST by using the PDATA= option. For a visual display of the unadjusted comparisons, use PROC ANOM in SAS/QC software. Each procedure is illustrated below.

The sample sizes and the number that respond positive in each of five groups are recorded in a SAS data set named P. The chi-square test from PROC FREQ indicates that some proportions might differ from the overall proportion (p=0.0537).

In PROC LOGISTIC, the default coding that is used for CLASS variables (effects coding) causes the parameter estimates to compare each group to the average. Because only k–1 parameters can be estimated for k groups, the parameter for the last group is not estimated. A CONTRAST statement can be added to test the last group. As shown in the "Class Level Information" table, the last group is coded as –1 for each of the design variables. The following statements compare the five group proportions to the overall proportion. The CONTRAST statement tests the last group proportion. The results indicate that only the last group differs from overall.

 proc logistic data=p;
    class group;
    model response/n = group;
    contrast '5 vs overall' group -1 -1 -1 -1;
    run;

In PROC MULTTEST, specify the CA test and a set of CONTRAST statements. The ith CONTRAST statement tests the hypothesis H₀: p_i = Σ_i p_i/k , where p_i is the positive response probability for the ith group and k is the number of groups. Note that this hypothesis can be written as (k–1)p_i – Σ_jp_j = 0, where j does not equal i. This suggests the coefficients to be used in the CONTRAST statements as shown below. You can use options in the PROC MULTTEST statement to adjust for the effect of multiple testing on the experimentwise error rate. For example, specify the BON option to use Bonferroni's method. Note that PROC MULTTEST cannot read data summarized as shown above, but by using the FREQ statement it can read data that is summarized so that there is one observation for each combination of group and response values. The following DATA step creates this form of summarized data. The results, both raw and adjusted for multiple testing, again indicate that only the last group differs from overall.

   data p2;
      set p;
      r=1; count=response; output;
      r=0; count=n-response; output;
      run;
   proc multtest data=p2 bon;
      class group;
      test ca(r);
      freq count;
      contrast "1 vs overall" 4 -1 -1 -1 -1;
      contrast "2 vs overall" -1 4 -1 -1 -1;
      contrast "3 vs overall" -1 -1 4 -1 -1;
      contrast "4 vs overall" -1 -1 -1 4 -1;
      contrast "5 vs overall" -1 -1 -1 -1 4;
      run;

Any of the p-value adjustment methods, including the resampling-based adjustments (bootstrap or permutation), can be used when the raw data is analyzed in PROC MULTTEST. The nonresampling methods can be used if you prefer to do the analysis in PROC LOGISTIC. To adjust the p-values from PROC LOGISTIC, specify an ODS OUTPUT statement to create data sets from the tables that contain the p-values. Then create a single data set of the p-values with a variable named RAW_P that contains all of the p-values. Use the PDATA= option in PROC MULTTEST to read the set of p-values and specify the appropriate option for your choice of nonresampling-based adjustment method. The BON option is used again in this example.

   proc logistic data=p;
      class group;
      model response/n = group;
      contrast '5 vs overall' group -1 -1 -1 -1;
      ods output contrasttest=ctt parameterestimates=pe;
      run;
   data probs;
      set pe ctt;
      if variable='Intercept' then delete;
      raw_p=probchisq;
      keep raw_p;
      run;
   proc multtest pdata=probs bon;
      run;

PROC ANOM can be used to present a visual display of the comparisons. Use the PCHART statement for comparisons of proportions. If a group's bar extends beyond the upper or lower decision limit (UDL or LDL), then that group's proportion differs significantly from the overall proportion. By default, the significance level is 0.05. The chart visually confirms the conclusions from PROC LOGISTIC and PROC MULTTEST—only the last group differs from the overall proportion (0.21).

   proc anom data=p;
      pchart response*group / groupn=n;
      run;

Operating System and Release Information