The FIND method may fail to update the variable used to supply the key
value after the key is successfully found in the hash table.  This
problem occurs when the variable specified in the FIND is also defined
as data in the hash table.  The following example illustrates the
incorrect behavior:

  data _null_;
    declare hash h();
    h.definekey ('from');
    h.definedata ('from','to');
    call missing(from,to);
    h.definedone ();
    from = 25;
    to  = 1;
    rc=h.add ();
    from = 35;
    to  = 25;
    rc=h.find(key:to);
    put "Variable 'to' is not updated: " rc= to= from=;
  run;

SAS log output:

  Variable 'to' is not updated: rc=0 to=25 from=25

The work around for this problem is to use a variable that has not
been defined as data in the hash table to supply the key value, as in
the following example:

  data _null_;
    declare hash h();
    h.definekey('from');
    h.definedata('from','to');
    call missing(from,to);
    h.definedone();
    from=25;
    to=1;
    rc=h.add();
    x=25;
    rc=h.find(key:x);
    put "Variable 'to' is updated: " rc= to= from=;
  run;

SAS log output:

  Variable 'to' is updated: rc=0 to=1 from=25


This problem corrected in SAS 9.2.

Operating System and Release Information