Documentation Example 1 for PROC HPCANDISC
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: HPCANEX1 */
/* TITLE: Documentation Example 1 for PROC HPCANDISC */
/* PRODUCT: HPSTAT */
/* SYSTEM: ALL */
/* KEYS: discriminant analysis, multivariate analysis */
/* PROCS: HPCANDISC */
/* DATA: FISHER (1936) IRIS DATA - SASHELP.IRIS */
/* */
/* SUPPORT: Ning Kang */
/* REF: PROC HPCANDISC, EXAMPLE 1 */
/* MISC: */
/****************************************************************/
title 'Fisher (1936) Iris Data';
proc hpcandisc data=sashelp.iris out=outcan distance anova;
id Species;
class Species;
var SepalLength SepalWidth PetalLength PetalWidth;
run;
proc template;
define statgraph scatter;
begingraph;
entrytitle 'Fisher (1936) Iris Data';
layout overlayequated / equatetype=fit
xaxisopts=(label='Canonical Variable 1')
yaxisopts=(label='Canonical Variable 2');
scatterplot x=Can1 y=Can2 / group=species name='iris';
layout gridded / autoalign=(topleft);
discretelegend 'iris' / border=false opaque=false;
endlayout;
endlayout;
endgraph;
end;
run;
proc sgrender data=outcan template=scatter;
run;