Getting Started Example 1 for PROC TRANSREG
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: TREGGS1 */
/* TITLE: Getting Started Example 1 for PROC TRANSREG */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: regression analysis, transformations */
/* PROCS: TRANSREG */
/* DATA: */
/* */
/* SUPPORT: saswfk UPDATE: July 25, 2010 */
/* REF: PROC TRANSREG, GETTING STARTED EXAMPLE 1 */
/* MISC: */
/****************************************************************/
title 'Gasoline and Emissions Data';
data gas;
set sashelp.gas;
if fuel in ('Ethanol', '82rongas', 'Gasohol');
run;
ods graphics on;
* Request a Spline Transformation of Equivalence Ratio;
proc transreg data=Gas solve ss2 plots=(transformation obp residuals);
model identity(nox) = spline(EqRatio / nknots=4);
run;
* Separate Curves and Intercepts;
proc transreg data=Gas solve ss2 additive plots=(transformation obp);
model identity(nox) = class(Fuel / zero=none) |
spline(EqRatio / nknots=4 after);
run;
* Separate Intercepts;
proc transreg data=Gas solve ss2 additive;
model identity(nox) = class(Fuel / zero=none)
spline(EqRatio / nknots=4);
run;
* Separate Curves and Intercepts with Penalized B-Splines;
proc transreg data=Gas ss2 plots=transformation lprefix=0;
model identity(nox) = class(Fuel / zero=none) * pbspline(EqRatio);
run;