Documentation Example 10 for PROC MIXED
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: mixexiso */
/* TITLE: Documentation Example 10 for PROC MIXED */
/* Isotonic Contrasts for Ordered Mean Values */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: linear mixed models */
/* Ordered hypothesis */
/* LSMESTIMATE */
/* PROCS: MIXED */
/* DATA: */
/* */
/* SUPPORT: Tianlin Wang */
/* REF: */
/* MISC: */
/****************************************************************/
data FerriteCores;
do Temp = 1 to 4;
do rep = 1 to 5; drop rep;
input MagneticForce @@;
output;
end;
end;
datalines;
10.8 9.9 10.7 10.4 9.7
10.7 10.6 11.0 10.8 10.9
11.9 11.2 11.0 11.1 11.3
11.4 10.7 10.9 11.3 11.7
;
proc mixed data=FerriteCores;
class Temp;
model MagneticForce = Temp;
lsmestimate Temp
'avg(1:1)<avg(2:4)' -3 1 1 1 divisor=3,
'avg(1:2)<avg(3:4)' -1 -1 1 1 divisor=2,
'avg(1:3)<avg(4:4)' -1 -1 -1 3 divisor=3
/ adjust=simulate(seed=1) cl upper;
ods select LSMestimates;
run;