Documentation Example 19 for PROC CALIS
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: CALEX03 */
/* TITLE: Documentation Example 19 for PROC CALIS */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: MSTRUCT, direct covariance structure analysis */
/* PROCS: CALIS */
/* DATA: */
/* */
/* SUPPORT: yiyung UPDATE: August 27, 2007 */
/* REF: PROC CALIS, Example 19 */
/* MISC: */
/****************************************************************/
data Wheaton(TYPE=COV);
_type_ = 'cov';
input _name_ $ 1-11 Anomie67 Powerless67 Anomie71 Powerless71
Education SEI;
label Anomie67='Anomie (1967)' Powerless67='Powerlessness (1967)'
Anomie71='Anomie (1971)' Powerless71='Powerlessness (1971)'
Education='Education' SEI='Occupational Status Index';
datalines;
Anomie67 11.834 . . . . .
Powerless67 6.947 9.364 . . . .
Anomie71 6.819 5.091 12.532 . . .
Powerless71 4.783 5.028 7.495 9.986 . .
Education -3.839 -3.889 -3.841 -3.625 9.610 .
SEI -21.899 -18.831 -21.748 -18.775 35.522 450.288
;
proc calis nobs=932 data=Wheaton psummary;
fitindex on(only)=[chisq df probchi] outfit=savefit;
mstruct
var = Anomie67 Powerless67 Anomie71 Powerless71;
matrix _COV_ [1,1] = phi1,
[2,2] = phi2,
[3,3] = phi1,
[4,4] = phi2,
[2,1] = theta1,
[3,1] = theta2,
[3,2] = theta1,
[4,1] = theta1,
[4,2] = theta3,
[4,3] = theta1;
run;
proc print data=savefit;
run;
proc calis nobs=932 data=Wheaton psummary;
mstruct
var = Anomie67 Powerless67 Anomie71 Powerless71;
matrix _COV_ [1,1] = phi1 phi2 phi1 phi2,
[2, ] = theta1,
[3, ] = theta2 theta1,
[4, ] = theta1 theta3 theta1;
fitindex on(only)=[chisq df probchi];
run;