Documentation Example 1 for PROC DISTANCE
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: distanx1 */
/* TITLE: Documentation Example 1 for PROC DISTANCE */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: Distance Matrix, Cluster Analysis */
/* PROCS: DISTANCE, CLUSTER, TREE, PRINT, SORT */
/* DATA: */
/* */
/* SUPPORT: saswfk UPDATE: July 25, 2010 */
/* REF: PROC DISTANCE, Example 1 */
/* MISC: */
/* */
/****************************************************************/
data divorce;
input State $15.
(Incompatibility Cruelty Desertion Non_Support Alcohol
Felony Impotence Insanity Separation) (1.) @@;
if mod(_n_,2) then input +4 @@; else input;
datalines;
Alabama 111111111 Alaska 111011110
Arizona 100000000 Arkansas 011111111
California 100000010 Colorado 100000000
Connecticut 111111011 Delaware 100000001
Florida 100000010 Georgia 111011110
Hawaii 100000001 Idaho 111111011
Illinois 011011100 Indiana 100001110
Iowa 100000000 Kansas 111011110
Kentucky 100000000 Louisiana 000001001
Maine 111110110 Maryland 011001111
Massachusetts 111111101 Michigan 100000000
Minnesota 100000000 Mississippi 111011110
Missouri 100000000 Montana 100000000
Nebraska 100000000 Nevada 100000011
New Hampshire 111111100 New Jersey 011011011
New Mexico 111000000 New York 011001001
North Carolina 000000111 North Dakota 111111110
Ohio 111011101 Oklahoma 111111110
Oregon 100000000 Pennsylvania 011001110
Rhode Island 111111101 South Carolina 011010001
South Dakota 011111000 Tennessee 111111100
Texas 111001011 Utah 011111110
Vermont 011101011 Virginia 010001001
Washington 100000001 West Virginia 111011011
Wisconsin 100000001 Wyoming 100000011
;
title 'Grounds for Divorce';
proc distance data=divorce method=djaccard absent=0 out=distjacc;
var anominal(Incompatibility--Separation);
id state;
run;
proc print data=distjacc(obs=10);
id state; var alabama--georgia;
title2 'First 10 States';
run;
title2;
proc cluster data=distjacc method=centroid
pseudo outtree=tree;
id state;
var alabama--wyoming;
run;
proc tree data=tree noprint n=9 out=out;
id state;
run;
proc sort;
by state;
run;
data clus;
merge divorce out;
by state;
run;
proc sort;
by cluster;
run;
proc print;
id state;
var Incompatibility--Separation;
by cluster;
run;