Getting Started Example 1 for PROC ROBUSTREG
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: rreggs1 */
/* TITLE: Getting Started Example 1 for PROC ROBUSTREG */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: Robust Regression */
/* */
/* PROCS: ROBUSTREG */
/* DATA: */
/* */
/* SUPPORT: Yonggang Yao */
/* REF: */
/* MISC: */
/****************************************************************/
data stack;
input x1 x2 x3 y exp $ @@;
datalines;
80 27 89 42 e1 80 27 88 37 e2
75 25 90 37 e3 62 24 87 28 e4
62 22 87 18 e5 62 23 87 18 e6
62 24 93 19 e7 62 24 93 20 e8
58 23 87 15 e9 58 18 80 14 e10
58 18 89 14 e11 58 17 88 13 e12
58 18 82 11 e13 58 19 93 12 e14
50 18 89 8 e15 50 18 86 7 e16
50 19 72 8 e17 50 19 79 8 e18
50 20 80 9 e19 56 20 82 15 e20
70 20 91 15 e21
;
proc robustreg data=stack;
model y = x1 x2 x3 / diagnostics leverage;
id exp;
test x3;
run;
ods graphics on;
proc robustreg data=stack plots=(rdplot ddplot histogram qqplot);
model y = x1 x2 x3;
run;
ods graphics off;
proc robustreg method=m(wf=bisquare(c=3.5)) data=stack;
model y = x1 x2 x3 / diagnostics leverage;
id exp;
test x3;
run;