Documentation Example 16 for PROC GLIMMIX
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: gmxex16 */
/* TITLE: Documentation Example 16 for PROC GLIMMIX */
/* Diallel Experiment with Multimember Random Effects */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: Generalized linear mixed models */
/* EFFECT statement */
/* Multimember effect */
/* PROCS: GLIMMIX */
/* DATA: */
/* */
/* SUPPORT: Oliver Schabenberger */
/* REF: Cockerham, C.C. and Weir, B.S. (1977) */
/* Quadratic Analyses of Reciprocal Crosses */
/* Biometrics, 33, 187-203 */
/* MISC: */
/****************************************************************/
data diallel;
label time = 'Flowering time in days';
do p = 1 to 8;
do m = 1 to 8;
if (m ne p) then do;
sym = trim(left(min(m,p))) || ',' || trim(left(max(m,p)));
do block = 1 to 2;
input time @@;
output;
end;
end;
end;
end;
datalines;
14.4 16.2 27.2 30.8 17.2 27.0 18.3 20.2 16.2 16.8 18.6 14.4 16.4 16.0
15.4 16.5 14.8 14.6 18.6 18.6 15.2 15.3 17.0 15.2 14.4 14.8 10.8 13.2
31.8 30.4 21.0 23.0 24.6 25.4 19.2 20.0 29.8 28.4 12.8 14.2 13.0 14.4
16.2 17.8 11.4 13.0 16.8 16.3 12.4 14.2 16.8 14.8 12.6 12.2 9.6 11.2
14.6 18.8 12.2 13.6 15.2 15.4 15.2 13.8 18.0 16.0 10.4 12.2 13.4 20.0
20.2 23.4 14.2 14.0 18.6 14.8 22.2 17.0 14.3 17.3 9.0 10.2 11.8 12.8
14.0 16.6 12.2 9.2 13.6 16.2 13.8 14.4 15.6 15.6 15.6 11.0 13.0 9.8
15.2 17.2 10.0 11.6 17.0 18.2 20.8 20.8 20.0 17.4 17.0 12.6 13.0 9.8
;
proc glimmix data=diallel outdesign(z)=zmat;
class block sym p m;
effect line = mm(p m);
model time = block;
random line sym p m p*m;
run;
proc print data=zmat(where=(block=1) obs=10);
var p m time _z1-_z8;
run;