Example 3 for PROC ADAPTIVEREG
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: adptex3 */
/* TITLE: Example 3 for PROC ADAPTIVEREG */
/* DESC: SPAM data set */
/* REF: UCI machine learning repository */
/* PRODUCT: STAT */
/* SYSTEM: ALL */
/* KEYS: */
/* PROCS: ADAPTIVEREG */
/* */
/* SUPPORT: Weijie Cai */
/****************************************************************/
%let base = http://archive.ics.uci.edu/ml/machine-learning-databases;
data spambase;
infile "&base/spambase/spambase.data" device=url dsd dlm=',';
input Make Address All _3d Our Over Remove Internet Order Mail Receive
Will People Report Addresses Free Business Email You Credit Your Font
_000 Money Hp Hpl George _650 Lab Labs Telnet _857 Data _415 _85
Technology _1999 Parts Pm Direct Cs Meeting Original Project Re Edu
Table Conference Semicol Paren Bracket Bang Dollar Pound Cap_Avg
Cap_Long Cap_Total Class;
run;
proc adaptivereg data=spambase seed=10359;
class Class;
model class = _000 _85 _415 _650 _857
_1999 _3d address addresses all
bang bracket business cap_avg cap_long
cap_total conference credit cs data
direct dollar edu email font
free george hp hpl internet
lab labs mail make meeting
money order original our over
paren parts people pm pound
project re receive remove report
semicol table technology telnet will
you your / additive dist=binomial;
partition fraction(test=0.333);
output out=spamout p(ilink);
run;
data test;
set spamout(where=(_ROLE_='TEST'));
if ((pred>0.5 & class=0) | (pred<0.5 & class=1))
then Error=0;
else error=1;
run;
proc freq data=test;
tables class*error/nocol;
run;
proc adaptivereg data=spambase seed=10359;
class Class;
model class = _000 _85 _415 _650 _857
_1999 _3d address addresses all
bang bracket business cap_avg cap_long
cap_total conference credit cs data
direct dollar edu email font
free george hp hpl internet
lab labs mail make meeting
money order original our over
paren parts people pm pound
project re receive remove report
semicol table technology telnet will
you your / maxbasis=61 additive dist=binomial;
partition fraction(test=0.333);
output out=spamout2 p(ilink);
run;