Standardization Method on Star Charts
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: SHWSTR3 */
/* TITLE: Standardization Method on Star Charts */
/* PRODUCT: QC */
/* SYSTEM: ALL */
/* KEYS: Shewhart Charts, Star Charts, */
/* PROCS: SHEWHART */
/* DATA: */
/* */
/* REF: SAS/QC Software: Usage and Reference, Version 6, */
/* First Edition, Volume 1 and Volume 2 */
/* */
/****************************************************************/
data Paint;
input hour pindexx pindexr pindexn thick
gloss defects dust humid temp;
datalines;
1 5.8 3.0 5 0.2550 0.6800 0.2550 0.2125 0.1700 0.5950
2 6.2 2.0 5 0.2975 0.5950 0.0850 0.1700 0.2125 0.5525
3 3.7 2.5 5 0.3400 0.3400 0.4250 0.2975 0.2550 0.2125
4 3.2 6.5 5 0.3400 0.4675 0.3825 0.3485 0.2125 0.2125
5 4.7 0.5 5 0.5100 0.4250 0.5950 0.4080 0.5100 0.4675
6 5.2 3.0 5 0.5100 0.3400 0.6800 0.5525 0.5525 0.5525
7 2.6 2.0 5 0.4250 0.0425 0.8500 0.5355 0.5525 0.2550
8 2.1 1.0 5 0.3400 0.0170 0.8075 0.5950 0.5950 0.1700
;
data Paintlim;
_var_ = 'pindex ';
_subgrp_ = 'hour ';
_type_ = 'estimate';
_limitn_ = 5;
_sigmas_ = 3;
_lclx_ = 2.395;
_mean_ = 3.875;
_uclx_ = 5.355;
_lclr_ = 0;
_r_ = 2.5625;
_uclr_ = 5.4184;
_stddev_ = 1.10171;
run;
data myspecs;
length _var_ $8
_label_ $16 ;
input _var_ _label_ _lspoke_ _sigmas_ _lsl_ _usl_ ;
datalines;
thick Thickness 1 . 0.25 0.50
gloss Gloss 1 . 0.10 0.60
defects Defects 1 . 0.10 0.60
dust Dust 2 3.0 . .
humid Humidity 2 0.0 . .
temp Temperature 2 0.0 . .
;
ods graphics on;
title 'Variables Related to Paint Index';
proc shewhart history=Paint limits=Paintlim;
xchart pindex * hour /
nolegend
odstitle = title
starvertices = ( thick gloss defects dust humid temp )
startype = wedge
starcircles = 0.0 1.0
lstarcircles = 2 2
starstart = -30
labelfont = simplex
starlegend = degrees
starspecs = myspecs
starlabel = high ;
run;