Hyper-Graeco-Latin Square
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: FACTEX7A */
/* TITLE: Hyper-Graeco-Latin Square */
/* PRODUCT: QC */
/* SYSTEM: ALL */
/* KEYS: Design of Experiments, Factorial Designs, */
/* PROCS: FACTEX */
/* DATA: */
/* */
/* REF: SAS/QC Software: Usage and Reference, Version 6, */
/* First Edition, Volume 1 and Volume 2 */
/* MISC: */
/* */
/****************************************************************/
proc factex;
factors Row Column t1-t3 / nlev=4;
size design=16;
model resolution=3;
output out=OrthArray t1 cvals=('A' 'B' 'C' 'D')
t2 cvals=('A' 'B' 'C' 'D')
t3 cvals=('A' 'B' 'C' 'D');
run;
data _null_;
array t{3} $ t1-t3;
array s{4} $ s1-s4; /* Buffer for holding each row */
file print; /* Direct printing to output screen */
do square=1 to 3;
put "Square " square ":";
n = 1;
do r=1 to 4;
do c=1 to 4;
set OrthArray point=n; n=n+1;
s{c}=t{square};
end;
put " " s1-s4;
end;
put;
end;
stop;
run;