Yarn Elongation: A Mixture Experiment
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: ADXEG5 */
/* TITLE: Yarn Elongation: A Mixture Experiment */
/* PRODUCT: QC */
/* SYSTEM: ALL */
/* KEYS: Design of Experiments, */
/* PROCS: */
/* DATA: */
/* REF: Cornell, J.A. (1981). Experiments with Mixtures. */
/* New York: John Wiley & Sons, pp. 32-35. */
/* MISC: ADX Macros are stored in the AUTOCALL library */
/* */
/* */
/* Cornell (1981) describes the use of a simplex-lattice design */
/* to study the properties of different yarn blends for */
/* draperies. The three constituents are */
/* * polyethylene (PETHYLN), */
/* * polystyrene (PSTYREN), and */
/* * polypropylene (PPROPYL). */
/* Only pure blends and binary blends are to be studied, so a */
/* simplex-lattice design of order 2 is called for. The yarn */
/* characteristic to be studied is */
/* * thread elongation (ELONG) */
/* */
/****************************************************************/
/*--------------------------------------------------------------*/
/* EXAMPLE 5: A SIMPLEX-LATTICE DESIGN FOR STUDYING YARN. */
/* SOURCE: CORNELL (1981). */
/*--------------------------------------------------------------*/
/*
/ For this example, we need only the mixture design macros: if we
/ haven't already included them, we do so now.
/---------------------------------------------------------------*/
%adxgen;
%adxmix;
%adxinit /* Initialize ADX environment. */
/*
/ The design is quite easy to construct.
/---------------------------------------------------------------*/
%adxsld(yarn,pethyln pstyren ppropyl,2)
/*
/ We can add the elongation data to the design with a DATA step:
/ two runs were made in the actual experiment for each pure
/ blend, and three for each 50:50 blend.
/---------------------------------------------------------------*/
data yarn; set yarn; drop npos i;
array x{3} pethyln pstyren ppropyl;
npos = 0;
do i = 1 to 3;
npos = npos + (x{i} > 0);
end;
if (npos = 1) then do i = 1 to 2;
input elong @@;
output;
end;
else do i = 1 to 3;
input elong @@;
output;
end;
cards;
16.8 16 10 9.7 11.8 8.8 10 17.7 16.4 16.6 15 14.8 16.1 11 12.4
run;
/*
/ Fit a general quadratic model to the data, except for the
/ intercept term (because of the sum-to-1 constraint for the
/ mixture levels.)
/---------------------------------------------------------------*/
proc glm;
model elong = pethyln|pstyren|ppropyl@2 / noint;
run;