Pharmaceutical Project
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: PMEX08 */
/* TITLE: Pharmaceutical Project */
/* PRODUCT: OR */
/* SYSTEM: ALL */
/* KEYS: CPM */
/* PROCS: CPM, NETDRAW, GANTT, SORT */
/* DATA: */
/* */
/* SUPPORT: UPDATE: */
/* REF: Example 8 of Project Management Examples Book */
/* MISC: */
/* */
/****************************************************************/
goptions border hpos=80 vpos=43
fby=swiss
ftitle=swiss
htitle=2
ftext=swiss
htext=1.5;
pattern1 v=solid c=blue;
pattern2 v=e c=blue;
pattern3 v=solid c=red;
pattern4 v=e c=red;
pattern5 v=x2 c=red;
pattern6 v=solid c=green;
pattern7 v=e c=magenta;
pattern8 v=solid c=magenta;
pattern9 v=x1 c=cyan;
title 'Pharmaceutical Project';
data pharm;
input act s1 s2 s3 s4 id & $30. months who $ subproj & $23.;
label subproj='Phase';
label who='Department';
label id='Activity';
cards;
1 3 4 5 6 Get Supplies for Studies 2.0 CH PRECLINICAL DEVELOPMENT
2 3 4 5 6 Develop Specifications/Methods 1.5 AP PRECLINICAL DEVELOPMENT
3 7 . . . Conduct Toxicity Studies 3.0 PT PRECLINICAL DEVELOPMENT
4 7 . . . Conduct Organ System Studies 6.0 PT PRECLINICAL DEVELOPMENT
5 7 8 . . Prepare Clinical Plans 3.0 MD PRECLINICAL DEVELOPMENT
6 7 8 . . Conduct Additional Studies 6.0 AP PRECLINICAL DEVELOPMENT
7 9 . . . Prepare IND 1.5 RG PRECLINICAL DEVELOPMENT
8 10 11 16 . Internal Review Board 1.0 MD PRECLINICAL DEVELOPMENT
9 10 11 16 . IND Filing 0 RG MILESTONES
10 12 . . . Phase I Clinical Studies 9.0 MD HUMAN PHARMACOLOGY
11 17 . . . Conduct Chemical/Mfg Research 6.0 CH HUMAN PHARMACOLOGY
12 13 . . . Internal SAFE Milestone 0 MD MILESTONES
13 14 . . . Phase II Clinical Studies 16.0 MD EFFICACY
14 15 . . . Internal GO Milestone 0 MD MILESTONES
15 19 . . . Phase III Clinical Studies 24.0 MD EXPANSION
16 19 . . . Conduct Carcinogenic Studies 36.0 PT HUMAN PHARMACOLOGY
17 18 . . . Arrange for Chem/Mfg Supplies 4.0 CH EFFICACY
18 19 . . . Write Chem/Mfg Sections of NDA 2.0 RG EXPANSION
19 20 . . . Prepare NDA 5.5 RG EXPANSION
20 . . . . NDA Filing 0 RG MILESTONES
;
data pharm;
set pharm;
if act=9 then lag1='FS_1';
if act=9 then lag2='FS_1';
if act=9 then lag3='FS_1';
if act=12 then lag1='FS_2';
if act=14 then lag1='FS_2';
run;
pattern1 v=e;
title2 'Initial Project Network';
proc netdraw graphics data=pharm;
actnet/compress activity=act successor=(s1-s4)
nodefid nolabel id=(id subproj) font=simplex;
run;
pattern1 v=s;
proc cpm data=pharm out=pharmout;
activity act;
successor s1 s2 s3 s4/lag=(lag1-lag3);
duration months;
id id subproj who;
run;
proc sort data=pharmout;
by e_start;
run;
title2 'General Development Process (in months)';
proc gantt graphics data=pharmout;
id id subproj who;
chart/duration=months scale=2
vmile="P" hmile=1 fmile=marker
nojobnum compress;
run;
proc gantt graphics data=pharmout precdata=pharm;
id id subproj who;
chart/duration=months scale=3
vmile="P" hmile=1 fmile=marker
act=act lag=(lag1-lag3) succ=(s1-s4)
nojobnum compress;
run;
proc sort data=pharmout;
by who e_start;
run;
title2 'Departmental Schedule';
proc gantt graphics data=pharmout;
by who;
id id subproj;
chart/duration=months scale=2
vmile="P" hmile=1 fmile=marker
nojobnum compress mindate=0;
run;
data pharmaoa;
input tail head id & $30. months who $ subproj & $23.;
label subproj='Phase';
label who='Department';
label id='Activity';
cards;
1 3 Get Supplies for Studies 2.0 CH PRECLINICAL DEVELOPMENT
2 3 Develop Specifications/Methods 1.5 AP PRECLINICAL DEVELOPMENT
3 4 Conduct Toxicity Studies 3.0 PT PRECLINICAL DEVELOPMENT
3 5 Conduct Organ System Studies 6.0 PT PRECLINICAL DEVELOPMENT
5 4 dummy 0.0 . .
3 6 Prepare Clinical Plans 3.0 MD PRECLINICAL DEVELOPMENT
6 4 dummy 0.0 . .
3 7 Conduct Additional Studies 6.0 AP PRECLINICAL DEVELOPMENT
7 6 dummy 0.0 . .
4 8 Prepare IND 1.5 RG PRECLINICAL DEVELOPMENT
6 9 Internal Review Board 1.0 MD PRECLINICAL DEVELOPMENT
8 9 IND Filing 1.0 RG .
9 14 Phase I Clinical Studies 9.0 MD HUMAN PHARMACOLOGY
9 10 dummy 0.0 . .
10 11 Conduct Chemical/Mfg Research 6.0 CH HUMAN PHARMACOLOGY
14 15 Internal SAFE Milestone 2.0 MD .
15 16 Phase II Clinical Studies 16.0 MD EFFICACY
16 17 Internal GO Milestone 2.0 MD .
17 13 Phase III Clinical Studies 24.0 MD EXPANSION
10 13 Conduct Carcinogenic Studies 36.0 PT HUMAN PHARMACOLOGY
11 12 Arrange for Chem/Mfg Supplies 4.0 CH EFFICACY
12 13 Write Chem/Mfg Sections of NDA 2.0 RG EXPANSION
13 18 Prepare NDA 5.5 RG EXPANSION
18 19 NDA Filing 0.0 RG .
;
proc cpm data=pharmaoa out=aoaout;
tailnode tail;
headnode head;
duration months;
id id subproj who;
run;
data aoaout;
set aoaout;
if id='dummy' then delete;
run;
proc sort data=aoaout;
by e_start;
run;
title2 'Activity on Arc Format (in months)';
proc gantt graphics data=aoaout;
id id subproj who;
chart/duration=months scale=2
vmile="P" hmile=1 fmile=marker
nojobnum compress;
run;