Combining MPS and FCMP Function Definitions (lsoe04)
/**********************************************************************/
/* */
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: lsoe04 */
/* TITLE: Combining MPS and FCMP Function Definitions (lsoe04) */
/* PRODUCT: OR */
/* SYSTEM: ALL */
/* KEYS: OR */
/* PROCS: OPTLSO, OPTMODEL, FCMP */
/* DATA: */
/* */
/* SUPPORT: UPDATE: */
/* REF: */
/* MISC: Example 4 from the OPTLSO chapter of the */
/* Local Search Optimization book. */
/* */
/**********************************************************************/
%macro lsompsmod(setold,setnew);
data &setnew(drop=i);
set &setold;
array FC{*} _CHARACTER_;
do i=1 to dim(FC);
FC[i] = compress(FC[i], "[]");
end;
run;
%mend;
proc optmodel;
var x{1..13} >= 0 <= 1;
for {i in 10..12} x[i].ub = 100;
min linobj = 5*sum{i in 1..4} x[i] - sum{i in 5..13} x[i];
con a1: 2*x[1] + 2*x[2] + x[10] + x[11] <= 10;
con a2: 2*x[1] + 2*x[3] + x[10] + x[12] <= 10;
con a3: 2*x[1] + 2*x[3] + x[11] + x[12] <= 10;
con a4: -8*x[1] + x[10] <= 0;
con a5: -8*x[2] + x[11] <= 0;
con a6: -8*x[3] + x[12] <= 0;
con a7: -2*x[4] - x[5] + x[10] <= 0;
con a8: -2*x[6] - x[7] + x[11] <= 0;
con a9: -2*x[8] - x[9] + x[12] <= 0;
save mps lindataOld;
quit;
%lsompsmod(lindataOld, lindata);
proc fcmp outlib=sasuser.myfuncs.mypkg;
function quadobj(x1,x2,x3,x4,f1);
return (f1 - 5*(x1**2 + x2**2 + x3**2 + x4**2));
endsub;
run;
data objdata;
input _id_ $ _function_ $ _sense_ $;
datalines;
f1 linobj .
f quadobj min
;
options cmplib = sasuser.myfuncs;
proc optlso
primalout = solution
mpsdata = lindata
objective = objdata;
performance nthreads=2;
run;
proc print data=solution;
run;