Zoned Network Diagrams (netdr11)
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: NETDR11 */
/* TITLE: Zoned Network Diagrams (netdr11) */
/* PRODUCT: OR */
/* SYSTEM: ALL */
/* KEYS: NETDRAW */
/* PROCS: CPM, NETDRAW */
/* DATA: */
/* */
/* SUPPORT: UPDATE: */
/* REF: Example 11 from the NETDRAW Chapter(PM User's Guide)*/
/* MISC: */
/* */
/****************************************************************/
/* Activity-on-Node representation of the project */
data widget;
format task $12. succ1-succ3 $12.;
input task & days succ1 & succ2 & succ3 & ;
datalines;
Approve Plan 5 Drawings Study Market Write Specs
Drawings 10 Prototype . .
Study Market 5 Mkt. Strat. . .
Write Specs 5 Prototype . .
Prototype 15 Materials Facility .
Mkt. Strat. 10 Test Market Marketing .
Materials 10 Init. Prod. . .
Facility 10 Init. Prod. . .
Init. Prod. 10 Test Market Marketing Evaluate
Evaluate 10 Changes . .
Test Market 15 Changes . .
Changes 5 Production . .
Production 0 . . .
Marketing 0 . . .
;
data details;
format task $12. phase $13. descrpt $30. ;
input task & phase $ descrpt & ;
datalines;
Approve Plan Planning Develop Concept
Drawings Engineering Prepare Drawings
Study Market Marketing Analyze Potential Markets
Write Specs Engineering Write Specifications
Prototype Engineering Build Prototype
Mkt. Strat. Marketing Develop Marketing Concept
Materials Manufacturing Procure Raw Materials
Facility Manufacturing Prepare Manufacturing Facility
Init. Prod. Manufacturing Initial Production Run
Evaluate Testing Evaluate Product In-House
Test Market Testing Test Product in Sample Market
Changes Engineering Engineering Changes
Production Manufacturing Begin Full Scale Production
Marketing Marketing Begin Full Scale Marketing
;
data network;
merge widget details;
run;
pattern1 v=e c=green;
pattern2 v=e c=red;
pattern3 v=e c=magenta;
pattern4 v=e c=blue;
pattern5 v=e c=cyan;
title j=l h=1.5 ' Project: Widget Manufacture';
title2 j=l h=1.5 ' Date: December 1, 2003';
footnote j=r h=1.5 'Zoned Network Diagram ';
proc netdraw data=network graphics;
actnet / act=task succ=(succ1 succ2 succ3)
separatearcs
zone=phase
zonepat
pcompress
htext=2;
label phase = 'Department';
run;
proc cpm data=network interval=weekday
out=sched date='1dec03'd;
activity task;
succ succ1 succ2 succ3;
duration days;
id phase;
run;
title j=l h=1.5 ' Project: Widget Manufacture';
title2 j=l h=1.5 ' Date: December 1, 2003';
footnote j=r h=1.5 'Zone and Timescale ';
proc netdraw data=sched graphics;
actnet / act=task succ=(succ1 succ2 succ3)
pcompress
carcs = blue ccritarcs=red
cref = cyan
caxis = magenta
lref = 33
id = (task)
nodefid
nolabel
boxwidth = 8
htext=2
separatearcs
timescale
mininterval=week
autoref
linear
zone=phase
zonespace;
label phase = 'Department';
run;