Resources

Activity Time Constraints (cpm12)

 /****************************************************************/
 /*          S A S   S A M P L E   L I B R A R Y                 */
 /*                                                              */
 /*    NAME: CPM12                                               */
 /*   TITLE: Activity Time Constraints (cpm12)                   */
 /* PRODUCT: OR                                                  */
 /*  SYSTEM: ALL                                                 */
 /*    KEYS: CPM                                                 */
 /*   PROCS: CPM                                                 */
 /*    DATA:                                                     */
 /*                                                              */
 /* SUPPORT:                             UPDATE:                 */
 /*     REF: Example 12 from the CPM Chapter (PM User's Guide)   */
 /*    MISC:                                                     */
 /*                                                              */
 /****************************************************************/

 /* Activity-on-Node representation of the project */

data widget12;
   input task $ 1-12 days succ1 $ 19-30 succ2 $ 33-44 succ3 $ 47-58
         adate date9. atype $ 70-72;
   format adate date7.;
   datalines;
Approve Plan   5  Drawings      Study Market  Write Specs
Drawings      10  Prototype                                15dec03   feq
Study Market   5  Mkt. Strat.
Write Specs    5  Prototype                                15dec03   sge
Prototype     15  Materials     Facility
Mkt. Strat.   10  Test Market   Marketing
Materials     10  Init. Prod.
Facility      10  Init. Prod.
Init. Prod.   10  Test Market   Marketing     Evaluate
Evaluate      10  Changes                                  27feb04   fle
Test Market   15  Changes                                  16feb04   ms
Changes        5  Production
Production     0
Marketing      0
;


title 'Activity Time Constraints';
title2 'Activity data set';
proc print data=widget12;
   run;

proc cpm data=widget12 date='1dec03'd
     xfervars interval=weekday;
   activity task;
   successor succ1 succ2 succ3;
   duration days;
   aligndate adate;
   aligntype atype;
   run;

title 'Activity Time Constraints';
title2 'Aligned Schedule';
proc print;
   id task;
   var adate atype e_: l_: t_float f_float;
   run;