Software Development Project (gantt0)
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: GANTT0 */
/* TITLE: Software Development Project (gantt0) */
/* PRODUCT: OR */
/* SYSTEM: ALL */
/* KEYS: GANTT */
/* PROCS: CPM, SORT, GANTT */
/* DATA: */
/* */
/* SUPPORT: UPDATE: */
/* REF: Getting Started section of the GANTT Chapter */
/* MISC: */
/* */
/****************************************************************/
options ps=60 ls=78;
data software;
input descrpt $char20.
duration 23-24
activity $ 27-34
succesr1 $ 37-44
succesr2 $ 47-54;
datalines;
Initial Testing 20 TESTING RECODE
Prel. Documentation 15 PRELDOC DOCEDREV QATEST
Meet Marketing 1 MEETMKT RECODE
Recoding 5 RECODE DOCEDREV QATEST
QA Test Approve 10 QATEST PROD
Doc. Edit and Revise 10 DOCEDREV PROD
Production 1 PROD
;
proc cpm data=software
out=intro1
interval=day
date='01mar04'd;
id descrpt;
activity activity;
duration duration;
successor succesr1 succesr2;
run;
title 'Project Schedule';
proc print data=intro1;
run;
options ls=100;
title 'Line-Printer Gantt Chart';
proc gantt lineprinter data=intro1;
run;
goptions colors=(black) cback=white
hpos=80 vpos=32 htext=1.1;
/* define the fill patterns for Gantt chart bars */
pattern1 v=r1;
pattern2 v=e;
pattern3 v=x1;
title h=2 'Graphics Gantt Chart';
proc gantt graphics data=intro1;
run;
title h=2 'Logic Gantt Chart';
proc gantt data=intro1;
chart / activity=activity successor=(succesr1-succesr2);
run;