Auxiliary and Alternate Resources (cpm27)
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: CPM27 */
/* TITLE: Auxiliary and Alternate Resources (cpm27) */
/* PRODUCT: OR */
/* SYSTEM: ALL */
/* KEYS: CPM */
/* PROCS: CPM */
/* DATA: Software Development */
/* */
/* SUPPORT: UPDATE: */
/* REF: */
/* MISC: Example 27 from CPM chapter of PM User's Guide */
/* Example 3 from CPM chapter of OR V8.1 Changes */
/* and Enhancements */
/* */
/****************************************************************/
data software;
input Activity & $15. dur act s1 s2 Programmer;
datalines;
Plans & Reqts 2 1 2 3 1
Product Design 3 2 4 5 1
Test Plan 3 3 6 7 .
Documentation 3 4 9 . 1
Code 10 5 8 . 1
Test Data 5 6 8 . .
Test Routines 5 7 8 . .
Test Product 6 8 9 . 1
Finish 0 9 . . .
;
data softaux;
set software;
Chris = .;
John = .;
Tester1 = .;
Tester2 = .;
run;
data resaux;
input per date7. otype $ resid $ 18-27 Programmer Chris John
Tester1 Tester2;
format per date7.;
datalines;
. altrate Programmer . 1 1 . .
. auxres Chris . . . .5 .
. auxres John . . . . .5
12apr04 reslevel . . 1 1 1 1
;
title 'Software Development';
title2 'Alternate and Auxiliary Resources';
title3 'Activity Data Set';
proc print data=softaux;
run;
title3 'Resource Data Set';
proc print data=resaux;
run;
proc cpm data=softaux out=sftaux rsched=rsftaux resin=resaux
date='12apr04'd interval=weekday resout=raux;
act act;
succ s1 s2;
dur dur;
res Programmer Chris John Tester1 Tester2 /
obstype=otype
period=per resid=resid
multalt rschedid=Activity;
id Activity;
run;
title 'Software Development: Alternate and Auxiliary Resources';
title3 'Resource Schedule Data Set';
options ls=80 ps=40;
proc print data=rsftaux heading=h;
id Activity;
run;