SAS/ETS User's Guide Example Programs

MDLINFOIN= and MDLINFOOUT= Data Sets

/*--------------------------------------------------------------

                    SAS Sample Library

        Name: x12ex07.sas
 Description: Example program from SAS/ETS User's Guide,
              The X12 Procedure
       Title: MDLINFOIN= and MDLINFOOUT= Data Sets
     Product: SAS/ETS Software
        Keys: seasonal adjustment of time series
        PROC: X12
       Notes:

--------------------------------------------------------------*/

data b1;
   input y @@;
   datalines;
   112 118 132 129
   121 135 148 148
   136 119 104 118
   115 126 141 135
   125 149 270 170
   158 133 114 140
;


title 'Model Identification Output to MDLINFOOUT= Data Set';
proc x12 data=b1 start='1980q1' interval=qtr MdlInfoOut=mdl;
   automdl;
   outlier;
run ;

proc print data=mdl;
run;

data pluseaster;
   _NAME_ = 'y';
   _MODELTYPE_ = 'REG';
   _MODELPART_ = 'PREDEFINED';
   _COMPONENT_ = 'SCALE';
   _PARMTYPE_ = 'EASTER';
   _DSVAR_ = 'EASTER';
   _VALUE_ = 25;
run;

data mdlpluseaster;
   set mdl;
run;

proc append base=mdlpluseaster data=pluseaster force;
run;


proc print data=mdlpluseaster;
run;

proc x12 data=b1 start='1980q1' interval=qtr
   MdlInfoIn=mdlpluseaster MdlInfoOut=mdl2;
   estimate;
run;

proc print data=mdl2;
run;
Resources

MDLINFOIN= and MDLINFOOUT= Data Sets
