乱数関数と乱数CALLルーチンの使用

このセクションのDATAステップで、乱数関数のプロパティをいくつか説明します。関数を呼び出すDATAステップは、各ステップとも初回呼び出しの初期シードが7となっているため、それぞれシード値7に基づく単一の疑似乱数ストリームを生成します。一部のDATAステップでは、各種の方法でシード値を変更します。関数呼び出しが1つしかないステップもあれば、複数の関数呼び出しが行われるステップもあります。これらのDATAステップは、どれもシードを変更しません。関数呼び出しに関連するシードは、最初の乱数関数の初回実行に使われるシードのみです。関数で独立したストリームを作成する方法はなく(作成するにはCALLルーチンを使用します)、新しいDATAステップを開始するしか、関数による乱数ストリームを再開する方法はありません。

次の例では複数のDATAステップを実行します。

  /* This DATA step produces a single stream of random numbers */
   /* based on a seed value of 7.                               */ 
data a;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
   a = ranuni (7); output;
run;

   /* This DATA step uses a DO statement to produce a single */
   /* stream of random numbers based on a seed value of 7.   */  
data b (drop = i);
   do i = 7 to 18;
      b = ranuni (i);
      output;
   end;
run;

   /* This DATA step uses a DO statement to produce a single */
   /* stream of random numbers based on a seed value of 7.   */ 
data c (drop = i);
   do i = 1 to 12;
      c = ranuni (7);
      output;
   end;
run;

   /* This DATA step calls the RANUNI and the RANNOR functions */
   /* and produces a single stream of random numbers based on  */
   /* a seed value of 7.                                       */   
data d;
   d = ranuni (7); f = ' '; output;
   d = ranuni (8); f = ' '; output;
   d = rannor (9); f = 'n'; output;
   d = .;          f = ' '; output;
   d = ranuni (0); f = ' '; output;
   d = ranuni (1); f = ' '; output;
   d = rannor (2); f = 'n'; output;
   d = .;          f = ' '; output;
   d = ranuni (3); f = ' '; output;
   d = ranuni (4); f = ' '; output;
   d = rannor (5); f = 'n'; output;
   d = .;          f = ' '; output;
run;

   /* This DATA step calls the RANNOR function and produces a     */
   /* single stream of random numbers based on a seed value of 7. */
data e (drop = i);
   do i = 1 to 6;
      e = rannor (7); output;
      e = .;          output;
   end;
run;

   /* This DATA step merges the output data sets that were */
   /* created from the previous five DATA steps.           */ 
data five;
   merge a b c d e;
run;

   /* This procedure writes the output from the merged data sets. */
proc print label data=five;
   options missing = ' ';
   label f = '00'x;
   title 'Single Random Number Streams';
run;

このプログラムの結果出力を次に示します。

出力データセットA、BおよびCの疑似乱数ストリームは同一です。出力データセットDのストリームには、RANUNI関数とRANNOR関数への呼び出しが併用されています。オブザベーション1、2、5、6、9、10では、RANUNIから返される値が先のストリームの値と完全に一致しています。"n"フラグ付きのオブザベーション3、7および11には、RANNOR関数から返された値が含まれています。関数呼び出しを併用しても、疑似乱数ストリームの生成には影響しません。結果はすべて、一様に分布した値の単一ストリームに基づいています。RANNORなどの他の関数によって変換されてから返されるものもあります。RANNOR関数の結果は、RANUNIへの2回の内部呼び出しによって生成されたものです。出力データセットDを作成するDATAステップは、次のステップを3回実行し、12のオブザベーションを作成します。

データセットEを作成するDATAステップでは、RANNORが6回呼び出されます。呼び出し時に毎回1行をスキップしますが、これはRANNORへの呼び出しごとに実行される2回のRANUNIへの内部呼び出しを補正するためです。データセットDを作成するDATAステップでRANNORから返される3つの値は、データセットEの対応する値と一致しています。

%SYSFUNCを使用し、マクロ言語を介してRANUNI関数を呼び出すと、疑似乱数ストリームが1つ作成されます。SASを終了し、新しいSASセッションを開始しない限りはシード値を変更できません。%SYSFUNCマクロは初回の起動時のみ、データセットA、BおよびCを生成したDATAステップと同一の疑似乱数ストリームを生成します。後続のマクロ呼び出しでは、単一ストリームの続きを生成します。

%macro ran;
   %do i = 1 %to 12;
      %let x = %sysfunc (ranuni (7)); 
      %put &x;
   %end;
   %mend;

%ran;

次の出力がログに書き込まれます。

10 %macro ran; 11 %do i = 1 %to 12; 12 %let x = %sysfunc (ranuni (7)); 13 %put &x; 14 %end; 15 %mend; 16 %ran; 0.29473798875451 0.79062100955779 0.79877014262544 0.81579051763554 0.45121804506109 0.78494144826426 0.80085421204606 0.72184205973606 0.34855818345609 0.46596586120592 0.73522999404707 0.66709365028287

乱数CALLルーチンを使用すると、単一のDATAステップで複数の疑似乱数ストリームを生成できます。各シード変数の初期化に異なるシード値を指定すると、生成される疑似乱数ストリームは計算量的には独立しますが、シード値を注意深く選択しなければ統計的に独立しません。

次の2つの例では、最悪のシナリオとなるようなシードを故意に選択しています。これらの例では、複数のシードを使って複数のストリームを作成する方法を示しています。これは非推奨の方法ですが、乱数CALLルーチンで複数のシードを使えます。

この例は、乱数CALLルーチンを使用し、複数のシードから疑似乱数的に分布した値の複数ストリームを生成できることを示しています。最初のDATAステップでは、正規分布の変数から3つのデータセットを作成します。2番目のDATAステップでは、一様分布の変数を作成します。SGSCATTERプロシジャ(SAS ODS Graphics: プロシジャガイドを参照)は、2種類の分布のそれぞれで、各変数ペア間にどのような関係があるかを示すために使用しています。

data normal;
   seed1 = 11111;
   seed2 = 22222;
   seed3 = 33333;
   do i = 1 to 10000;
      call rannor(seed1, x1);
      call rannor(seed2, x2);
      call rannor(seed3, x3);
      output;
   end;
run;

data uniform;
   seed1 = 11111;
   seed2 = 22222;
   seed3 = 33333;
   do i = 1 to 10000;
      call ranuni(seed1, x1);
      call ranuni(seed2, x2);
      call ranuni(seed3, x3);
      output;
   end;
run;

proc sgscatter data = normal;
   title 'Nonindependent Random Normal Variables';
   plot x1*x2 x1*x3 x3*x2 / markerattrs = (size = 1);
run;

proc sgscatter data = uniform;
   title 'Nonindependent Random Uniform Variables';
   plot x1*x2 x1*x3 x3*x2 / markerattrs = (size = 1);
run;

1番目のプロット(複数のシードから作成した複数のストリーム:独立していないランダムな正規変数)では、正規変数が直線的な相関関係にはないように見えますが、明らかに独立していません。2番目のプロット(複数のシードから作成した複数のストリーム:独立していないランダムな一様変数 )では、一様変数が明確に相関関係にあることがわかります。この部類の乱数ジェネレータでは、ストリームが独立している保証は一切ありません。

次の例では、3つの異なるシードとCALL RANUNIルーチンを使用して複数のストリームを作成しています。

data uniform(drop=i);
   seed1 = 255793849;
   seed2 =1408147117;
   seed3 = 961782675;
   do i=1 to 10000;
      call ranuni(seed1, x1);
      call ranuni(seed2, x2);
      call ranuni(seed3, x3);
      i2 = lag(x2);
      i3 = lag2(x3);
      output;
   end;
label i2='Lag(x2)' i3='Lag2(x3)';
run;

title 'Random Uniform Variables with Overlapping Streams';
proc sgscatter data=uniform;
   plot x1*x2 x1*x3 x3*x2 / markerattrs = (size = 1);
run;

proc sgscatter data=uniform;
   plot i2*x1 i3*x1 / markerattrs = (size = 1);
run;
 
proc print noobs data=uniform(obs=10);
run;

1番目のプロット(CALL RANUNIで異なるシードを使用する:重複するストリームを持つランダムな一様分布変数:プロット1)は、変数が統計的に独立した、期待どおりの結果を示しています。ただし、2番目のプロット(CALL RANUNIで異なるシードを使用する:重複するストリームを持つランダムな一様分布変数:プロット2 )と最初の10のオブザベーションのリストは、2つのストリームでほぼ完全な重複があることを示しています。x1の最後の9999個の値はx2の最初の9999個の値と一致しており、x1の最後の9998個の値はx3の最初の9998個の値と一致しています。言い換えれば、x1とlag(x2)に加え、x1とlag2(x3)の間の非欠損部分に完全な一致が存在します。1番目のプロットのように、一見ストリームが独立しているようでも重複の可能性があります。ストリームの用途によっては、これは望ましくありません。

実際には、個別のシードをランダムに選んで小さいストリームを複数作成すれば、最初の2つの例に示したような問題にはおそらく遭遇しません。 CALL RANUNIで異なるシードを使用する:重複するストリームを持つランダムな一様分布変数:プロット2では、最悪のシナリオとなるようなシードを故意に選択しています。

ストリームの作成は1つにとどめるのが安全です。複数のストリームを作成すると、ストリームが長くなるにつれて、ストリームが重複する可能性が増します。

プログラムで関数を使用する場合は、DATAステップ内で複数のシードを指定して複数の疑似乱数ストリームは生成できません。

RANUNI関数を使用し、単一のシードで同一のストリームから複数の変数を作成する最も安全な方法を次の例に示します。

次の例では、重複するストリームを持つランダムな一様分布変数を作成するのにRANUNI関数を使用しています。この例は、RANUNI関数を使用して複数の変数を作成する最も安全な方法を示しています。すべての変数が単一のシードで同一のストリームから作成されます。

data uniform(drop=i);
   do i = 1 to 10000;
      x1 = ranuni(11111);
      x2 = ranuni(11111);
      x3 = ranuni(11111);
      i2 = lag(x2);
      i3 = lag2(x3);
      output;
   end;
label i2 = 'Lag(x2)' i3 = 'Lag2(x3)';
run;

title 'Random Uniform Variables with Overlapping Streams';
proc sgscatter data = uniform;
   plot x1*x2 x1*x3 x3*x2 / markerattrs = (size = 1);
run;

proc sgscatter data = uniform;
   plot i2*x1 i3*x1 / markerattrs = (size = 1);
run;

,例:重複するストリームを持つランダムな一様分布変数を生成するでは、変数が独立しているように見えます。ただし、このプログラミング手法でも全般的に問題なく機能するとは限りません。乱数関数とCALLルーチンの周期は2³¹ - 2(およそ21億)以下でしかありません。この限界に達するとストリームは繰り返されます。複雑なシミュレーションをこなす現代のコンピュータなら、ストリーム全体をわずか数分で簡単に使い果たしてしまいます。

RANUNIのストリームが使い果たされない限り、通常は単一のストリームを開始、停止するのに乱数CALLルーチンを使用します。たとえば、SASで反復を実行し、停止して結果を評価し、ストリームの停止点から再開したい場合を考えます。次の例ではこの原理を説明しています。

この例では、5つの数値のストリームを生成、停止および再開してから同じストリームからさらに5つの数値を生成し、結果を組み合わせて比較用の完全なストリームを生成します。最初のDATAステップでは、次のステップで開始シードに使用するために、乱数シードの状態をマクロ変数シードに格納しています。この例の個別ストリームの出力は、完全なストリームに一致します。

data u1(keep=x);
   seed = 104;
   do i = 1 to 5;
      call ranuni(seed, x);
      output;
   end;
   call symputx('seed', seed);
run;

data u2(keep=x);
   seed = &seed;
   do i = 1 to 5;
      call ranuni(seed, x);
      output;
   end;
run;

data all;
   set u1 u2;
   z = ranuni(104);
run;

proc print label;
   title 'Random Uniform Variables with Overlapping Streams';
   label x = 'Separate Streams' z = 'Single Stream';
run;

シードの変更にCALLルーチンを使用する場合の結果は、関数を使用してシードを変更する場合と異なります。この違いの例を次に示します。

data seeds;
   retain Seed1 Seed2 Seed3 104;
   do i = 1 to 10;
      call ranuni(Seed1,X1);
      call ranuni(Seed2,X2);
      X3 = ranuni(Seed3);
      if i = 5 then do;
         Seed2 = 17;
         Seed3 = 17;
      end;
      output;
   end;
run;

proc print data = seeds;
   title 'Random Uniform Variables with Overlapping Streams';
   id i;
run;

CALL RANUNIステートメントでi=5のときにSeed2を変更すると、X2のストリームはX1のストリームから強制的に逸脱させられます。ただし、RANUNI関数でSeed3を変更した場合には影響はありません。何も変更がなかったかのようにX3のストリームが続行するため、X1とX3のストリームは同一です。