Example 62.8 Reading Mixed Model Results with Classification Covariates

This example creates data sets that contains parameter estimates and corresponding covariance matrices with classification variables computed by a mixed regression model analysis for a set of imputed data sets. These estimates are then combined to generate valid statistical inferences about the model parameters.

The following statements use PROC MIXED to generate the parameter estimates and covariance matrix for each imputed data set:

```proc mixed data=outfish2;
class Species;
model Length= Species Width/ solution;
by _Imputation_;
ods output SolutionF=mxparms;
run;
```

The following statements display (in Output 62.8.1) the output mixed model coefficients from PROC MIXED for the first two imputed data sets:

```proc print data=mxparms (obs=10);
var _Imputation_ Effect Species Estimate StdErr;
title 'MIXED Model Coefficients (First Two Imputations)';
run;
```

Output 62.8.1: PROC MIXED Model Coefficients

 MIXED Model Coefficients (First Two Imputations)

Obs _Imputation_ Effect Species Estimate StdErr
1 1 Intercept   4.5106 0.8244
2 1 Species Parkki 1.5774 0.7020
3 1 Species Perch 0 .
4 1 Width   5.2585 0.1599
5 2 Intercept   4.5250 0.8771
6 2 Species Parkki 1.4885 0.7693
7 2 Species Perch 0 .
8 2 Width   5.2389 0.1701
9 3 Intercept   4.8906 0.7724
10 3 Species Parkki 0.7972 0.7396

The following statements use the MIANALYZE procedure with an input PARMS= data set:

```proc mianalyze parms(classvar=full)=mxparms;
class Species;
modeleffects Intercept Species Width;
run;
```

The Variance Information table in Output 62.8.2 displays the between-imputation, within-imputation, and total variances for combining complete-data inferences.

Output 62.8.2: Variance Information

The MIANALYZE Procedure

Variance Information
Parameter Species Variance DF Relative
Increase
in Variance
Fraction
Missing
Information
Relative
Efficiency
Between Within Total
Intercept   0.035884 0.687242 0.730303 1150.5 0.062658 0.060595 0.988026
Species Parkki 0.097719 0.541354 0.658616 126.18 0.216610 0.190769 0.963248
Species Perch 0 . . . . . .
Width   0.000873 0.026312 0.027359 2726.5 0.039828 0.039007 0.992259

The Parameter Estimates table in Output 62.8.3 displays the combined parameter estimates with associated standard errors.

Output 62.8.3: Parameter Estimates

Parameter Estimates
Parameter Species Estimate Std Error 95% Confidence Limits DF Minimum Maximum Theta0 t for H0:
Parameter=Theta0
Pr > |t|
Intercept   4.560311 0.854578 2.88360 6.237016 1150.5 4.419502 4.890594 0 5.34 <.0001
Species Parkki 1.318070 0.811552 -0.28794 2.924083 126.18 0.797233 1.577380 0 1.62 0.1068
Species Perch 0 . . . . 0 0 0 . .
Width   5.265971 0.165407 4.94164 5.590307 2726.5 5.238887 5.313877 0 31.84 <.0001