The MI Procedure

This example applies the MCMC method to the Fitness1 data set in which the variable Oxygen is transformed. Assume that Oxygen is skewed and can be transformed to normality with a logarithmic transformation. The following statements invoke the MI procedure and specify the transformation. The TRANSFORM statement specifies the log transformation for Oxygen. Note that the values displayed for Oxygen in all of the results correspond to transformed values.

proc mi data=Fitness1 seed=32937921 mu0=50 10 180 out=outex13;
   transform log(Oxygen);
   mcmc chain=multiple displayinit;
   var Oxygen RunTime RunPulse;
run;

The “Missing Data Patterns” table in Output 57.13.1 lists distinct missing data patterns with corresponding statistics for the Fitness1 data. Note that the values of Oxygen shown in the tables are transformed values.

The “Variable Transformations” table in Output 57.13.2 lists the variables that have been transformed.

The “Initial Parameter Estimates for MCMC” table in Output 57.13.3 displays the starting mean and covariance estimates used in the MCMC method.

Output 57.13.4 displays variance information from the multiple imputation.

Output 57.13.5 displays parameter estimates from the multiple imputation. Note that the parameter value of has also been transformed using the logarithmic transformation.

The following statements list the first 10 observations of the data set outex13 in Output 57.13.6. Note that the values for Oxygen are in the original scale.

proc print data=outex13(obs=10);
   title 'First 10 Observations of the Imputed Data Set';
run;

Note that the results in Output 57.13.6 can also be produced from the following statements without using a TRANSFORM statement. A transformed value of log(50)=3.91202 is used in the MU0= option.

data temp;
   set Fitness1;
   LogOxygen= log(Oxygen);
run;
proc mi data=temp seed=14337921 mu0=3.91202 10 180 out=outtemp;
   mcmc chain=multiple displayinit;
   var LogOxygen RunTime RunPulse;
run;
data outex13;
   set outtemp;
   Oxygen= exp(LogOxygen);
run;