Getting Started: SIMNORMAL Procedure

The following example illustrates the use of PROC SIMNORMAL to generate variable values conditioned on a set of related or correlated variables.

Suppose you are given a sample of size 50 from ten normally distributed, correlated random variables, . The first five variables represent input variables for a chemical manufacturing process, and the last five are output variables.

First, the data are input and the correlation structure is determined by using PROC CORR, as in the following statements. The results are shown in Figure 81.1.

data a;
   input in1-in5 out1-out5;
   datalines;
 9.3500    10.0964     7.3177    10.3617    10.3444    9.4612  
10.7443     9.9026     9.0144    11.7968

   ... more lines ...   

 8.9174     9.9623     9.5742     9.9713
;

proc corr data=a cov nocorr outp=outcov;
  var in1-in5 out1-out5;
run;

After the mean and correlation structure are determined, any subset of these variables can be simulated. Suppose you are interested in a particular function of the output variables for two sets of values of the input variables for the process. In particular, you are interested in the mean and variability of the following function over 500 runs of the process conditioned on each set of input values:

Although the distribution of these quantities could be determined theoretically, it is simpler to perform a conditional simulation by using PROC SIMNORMAL.

To do this, you first append a _TYPE_=’COND’ observation to the covariance data set produced by PROC CORR for each group of input values:

data cond1;
   _TYPE_='COND';
   in1 = 8;
   in2 = 10.5;
   in3 = 12;
   in4 = 13.5;
   in5 = 14.4;
run;

data cond2;
   _TYPE_='COND';
   in1 = 15.4;
   in2 = 13.7;
   in3 = 11;
   in4 = 7.9;
   in5 = 5.5;
run;

Next, each of these conditioning observations is appended to a copy of the OUTP=OUTCOV data from the CORR procedure, as in the following statements. A new variable, INPUT, is added to distinguish the sets of input values. This variable is used as a BY variable in subsequent steps.

data outcov1;
   input=1;
   set outcov cond1;
run;

data outcov2;
   input=2;
   set outcov cond2;
run;

Finally, these two data sets are concatenated:

data outcov;
  set outcov1 outcov2;
run;

proc print data=outcov;
   where (_type_ ne 'COV');
run;

Figure 81.2 shows the added observations.

The specification of PROC SIMNORMAL now follows from the problem description. The condition variables are IN1–IN5, the analysis variables are OUT1–OUT5, and 500 realizations are required. A seed value can be chosen arbitrarily, or the system clock can be used. Note that in the following statements, the simulation is done for each of the values of the BY variable INPUT:

proc simnormal data=outcov(type=cov) out=osim numreal=500 seed=33179;
   by input;
   var out1-out5;
   cond in1-in5;
run;

data b; 
   set osim;
   denom = sum(of out1-out5);
   if abs(denom) < 1e-8 then ff = .;
   else ff = (out1-out3)/denom;
run;

The DATA step that follows the simulation computes the function ; in the following statements the UNIVARIATE procedure computes the simple statistics for this function for each set of conditioning input values. This is shown in Figure 81.3, and Figure 81.4 shows the distribution of the function values for each set of input values by using the SGPANEL procedure.

proc univariate data=b;
   by input;
   var ff;
run;      

title;
proc sgpanel data=b;
   panelby input;
   refline 0 / axis=x;
   density ff;
run;

Figure 81.4 Frequency Plot for ff for Each Set of Input Values