Example 55.5 Reading Generalized Linear Model Results

This example creates data sets containing parameter estimates and corresponding covariance matrices computed by a generalized linear model analysis for a set of imputed data sets. These estimates are then combined to generate valid statistical inferences about the model parameters.

The following statements use PROC GENMOD to generate the parameter estimates and covariance matrix for each imputed data set:

 proc genmod data=outmi;
    model Oxygen= RunTime RunPulse/covb;
    by _Imputation_;
    ods output ParameterEstimates=gmparms
               ParmInfo=gmpinfo
               CovB=gmcovb;
 run;

The following statements print (in Output 55.5.1) the output parameter estimates and covariance matrix from PROC GENMOD for the first two imputed data sets:

proc print data=gmparms (obs=8);
   var _Imputation_ Parameter Estimate StdErr;
   title 'GENMOD Model Coefficients (First Two Imputations)';
run;

The following statements display the parameter information table in Output 55.5.2. The table identifies parameter names used in the covariance matrices. The parameters Prm1, Prm2, and Prm3 are used for the effects Intercept, RunTime, and RunPulse, respectively, in each covariance matrix.

proc print data=gmpinfo (obs=6);
   title 'GENMOD Parameter Information (First Two Imputations)';
run;

The following statements display (in Output 55.5.3) the output covariance matrices from PROC GENMOD for the first two imputed data sets. Note that the GENMOD procedure computes maximum likelihood estimates for each covariance matrix.

proc print data=gmcovb (obs=8);
   var _Imputation_ RowName Prm1 Prm2 Prm3;
   title 'GENMOD Covariance Matrices (First Two Imputations)';
run;

The following statements use the MIANALYZE procedure with input PARMS=, PARMINFO=, and COVB= data sets:

proc mianalyze parms=gmparms covb=gmcovb parminfo=gmpinfo;
   modeleffects Intercept RunTime RunPulse;
run;

Since the GENMOD procedure computes maximum likelihood estimates for the covariance matrix, the EDF= option is not used. The resulting model coefficients are identical to the estimates in Output 55.3.3 in Example 55.3. However, the standard errors are slightly different because in this example, maximum likelihood estimates for the standard errors are combined without the EDF= option, whereas in Example 55.3, unbiased estimates for the standard errors are combined with the EDF= option.