Example 32.2 Financial Data – Stock Dividends

The following data set contains the average dividend yields for 15 utility stocks in the United States. The observations are names of the companies, and the variables correspond to the annual dividend yields for the period 1986–1990. The objective is to group similar stocks into clusters.

Before the cluster analysis is performed, the correlation similarity is chosen for measuring the closeness between each observation. Since distance type of measures are required by the CLUSTER procedure, METHOD=DCORR is used in the PROC DISTANCE statement to transform the correlation measures to the distance measures. Notice that in Output 32.2.1, all the values in the distance matrix are between 0 and 2.

The macro function DO_CLUSTER performs cluster analysis and presents the results in graphs. The CLUSTER procedure performs hierarchical clustering by using agglomerative methods based on the distance data created from the previous PROC DISTANCE statement. The resulting tree diagrams can be saved into an output data set and can later be plotted by the TREE procedure. Since the CCC statistic is not suitable for distance type of data, only the Pseudo statistic is requested to identify the number of clusters.

Two clustering methods are invoked in the DO_CLUSTER macro: Ward’s and the average linkage methods. Since the results of the Pseudo statistic from both Ward’s and the average linkage methods contain many missing values, only the plot of the Pseudo statistic versus the number of clusters is requested by specifying PLOTS(ONLY)= PSF in the PROC CLUSTER statement.

Both Output 32.2.2 and Output 32.2.3 suggest a possible clusters of 4. Both methods produce the same clustering result, as shown in Output 32.2.4 and Output 32.2.5. The four clusters are as follows:

• Cincinnati G&E and Detroit Edison

• Texas Utilities and Pennsylvania Power & Light

• Union Electric, Iowa-Ill Gas & Electric, Oklahoma Gas & Electric, and Wisconsin Energy

• Orange & Rockland Utilities, Kentucky Utilities, Kansas Power & Light, Allegheny Power, Green Mountain Power, Dominion Resources, and Minnesota Power & Light

data stock;
   title 'Stock Dividends';
   input Company &$26.  Div_1986 Div_1987 Div_1988 Div_1989 Div_1990;
   datalines;
Cincinnati G&E               8.4    8.2    8.4    8.1    8.0
Texas Utilities              7.9    8.9   10.4    8.9    8.3
Detroit Edison               9.7   10.7   11.4    7.8    6.5
Orange & Rockland Utilities  6.5    7.2    7.3    7.7    7.9
Kentucky Utilities           6.5    6.9    7.0    7.2    7.5
Kansas Power & Light         5.9    6.4    6.9    7.4    8.0
Union Electric               7.1    7.5    8.4    7.8    7.7
Dominion Resources           6.7    6.9    7.0    7.0    7.4
Allegheny Power              6.7    7.3    7.8    7.9    8.3
Minnesota Power & Light      5.6    6.1    7.2    7.0    7.5
Iowa-Ill Gas & Electric      7.1    7.5    8.5    7.8    8.0
Pennsylvania Power & Light   7.2    7.6    7.7    7.4    7.1
Oklahoma Gas & Electric      6.1    6.7    7.4    6.7    6.8
Wisconsin Energy             5.1    5.7    6.0    5.7    5.9
Green Mountain Power         7.1    7.4    7.8    7.8    8.3
;

proc distance data=stock method=dcorr out=distdcorr;
   var interval(div_1986 div_1987 div_1988 div_1989 div_1990);
   id company;
run;

proc print data=distdcorr;
   id company;
   title2 'Distance Matrix for 15 Utility Stocks';
run;
title2;

/* performs cluster analysis and plots the results */
%macro do_cluster(clusmtd);

%let clusmtd = %upcase(&clusmtd);
title2 "Cluster Method = &clusmtd";   

/* compute pseudo statistic versus number of clusters and create plot */
proc cluster data=distdcorr method=&clusmtd outtree=Tree 
             pseudo plots(only)= psf;
   id company;
run;

/* plot tree diagram */
proc tree data=Tree horizontal;
   id company;
run;
%mend;

ods graphics on; 

/* METHOD=WARD */
%do_cluster(ward);

/* METHOD=AVERAGE */
%do_cluster(average);

ods graphics off; 

Output 32.2.2 Pseudo F versus Number of Clusters When METHOD=WARD

Output 32.2.3 Pseudo F versus Number of Clusters When METHOD=AVERAGE

Output 32.2.4 Tree Diagram of Clusters versus Semipartial R-Square Values When METHOD=WARD

Output 32.2.5 Tree Diagram of Clusters versus Average Distance between Clusters When METHOD=AVERAGE